ΑΕΠΠ: Δικά μας Προγράμματα

Aggelos!

Νεοφερμένος

Ο Aggelos! αυτή τη στιγμή δεν είναι συνδεδεμένος. Είναι 33 ετών και Απόφοιτος. Έχει γράψει 46 μηνύματα.
Πολύ καλή δουλειά αλλα βγαίνω πάντα ισοπαλία :D ...
 

Σημείωση: Το μήνυμα αυτό γράφτηκε 15 χρόνια πριν. Ο συντάκτης του πιθανόν να έχει αλλάξει απόψεις έκτοτε.

EpaRon

Εκκολαπτόμενο μέλος

Ο Νώντας αυτή τη στιγμή δεν είναι συνδεδεμένος. Είναι Φοιτητής και μας γράφει απο Λευκάδα (Λευκάδα). Έχει γράψει 203 μηνύματα.
Πολύ καλή προσπάθεια!!!
 

Σημείωση: Το μήνυμα αυτό γράφτηκε 15 χρόνια πριν. Ο συντάκτης του πιθανόν να έχει αλλάξει απόψεις έκτοτε.

Panos_K

Νεοφερμένος

Ο Παναγιωτης αυτή τη στιγμή δεν είναι συνδεδεμένος. Είναι 33 ετών, Φοιτητής και μας γράφει απο Πέλλα (Πέλλα). Έχει γράψει 4 μηνύματα.
Στο προγραμμα SUDOKU καντε αντικατασταση την διαδικασια "ΕΙΣΟΔΟΣ(ΣΟΥ,ΠΙΑΣΜΕΝΕΣ)"
με την παρακατω :)
Ειναι κορυφη:D

Code:
ΔΙΑΔΙΚΑΣΙΑ ΕΙΣΟΔΟΣ(ΣΟΥ,ΠΙΑΣΜΕΝΕΣ)
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ:Χ,Υ,ΑΡ,ΣΟΥ[81],ΘΧ,ΘΥ
  ΛΟΓΙΚΕΣ:ΠΙΑΣΜΕΝΕΣ[81]
  ΧΑΡΑΚΤΗΡΕΣ:Κ
ΑΡΧΗ
  ΠΗΓΑΙΝΕ_ΧΥ 44,15
  ΓΡΑΨΕ '-> **By Panos_K** <-'
  ΠΗΓΑΙΝΕ_ΧΥ 30,1
  ΓΡΑΨΕ 'Χρησιμοποιησε τα πληκτρα [8,2,4,6] για αλλαγη θεσης'
  ΠΗΓΑΙΝΕ_ΧΥ 30,3
  ΓΡΑΨΕ 'Πιεσε το [5] για εισαγωγη αριθμου στην θεση'
  ΠΗΓΑΙΝΕ_ΧΥ 30,5
  ΓΡΑΨΕ '!!Αν βαλεις το [0] σε μια θεση, αδειαζει η θεση!!'
  ΠΗΓΑΙΝΕ_ΧΥ 30,7
  ΓΡΑΨΕ 'Πληκτρολογησε τον αριθμο και επειτα πιεσε <Enter>'
  ΠΗΓΑΙΝΕ_ΧΥ 30,9
  ΓΡΑΨΕ 'Για να δεις την λυση πιεσε [0]'
  ΠΗΓΑΙΝΕ_ΧΥ 1,1
  ΓΡΑΨΕ '+--+--+--#--+--+--#--+--+--+'
  ΓΡΑΨΕ '|  |  |  |  |  |  |  |  |  |'
  ΓΡΑΨΕ '+--+--+--#--+--+--#--+--+--+'
  ΓΡΑΨΕ '|  |  |  |  |  |  |  |  |  |'
  ΓΡΑΨΕ '+--+--+--#--+--+--#--+--+--+'
  ΓΡΑΨΕ '|  |  |  |  |  |  |  |  |  |'
  ΓΡΑΨΕ '+++++++++#++++++++#+++++++++'
  ΓΡΑΨΕ '|  |  |  |  |  |  |  |  |  |'
  ΓΡΑΨΕ '+--+--+--#--+--+--#--+--+--+'
  ΓΡΑΨΕ '|  |  |  |  |  |  |  |  |  |'
  ΓΡΑΨΕ '+--+--+--#--+--+--#--+--+--+'
  ΓΡΑΨΕ '|  |  |  |  |  |  |  |  |  |'
  ΓΡΑΨΕ '+++++++++#++++++++#+++++++++'
  ΓΡΑΨΕ '|  |  |  |  |  |  |  |  |  |'
  ΓΡΑΨΕ '+--+--+--#--+--+--#--+--+--+'
  ΓΡΑΨΕ '|  |  |  |  |  |  |  |  |  |'
  ΓΡΑΨΕ '+--+--+--#--+--+--#--+--+--+'
  ΓΡΑΨΕ '|  |  |  |  |  |  |  |  |  |'
  ΓΡΑΨΕ '+++++++++#++++++++#+++++++++'
  ΘΧ <-- 3
  ΘΥ <-- 2
  ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
    ΠΗΓΑΙΝΕ_ΧΥ ΘΧ,ΘΥ
    ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
      Κ <-- READKEY
      ΑΝ Κ='8' ΤΟΤΕ
        ΘΥ <-- ΘΥ-2
      ΑΛΛΙΩΣ_ΑΝ Κ='6' ΤΟΤΕ
        ΘΧ <-- ΘΧ+3
      ΑΛΛΙΩΣ_ΑΝ Κ='4' ΤΟΤΕ
        ΘΧ <-- ΘΧ-3
      ΑΛΛΙΩΣ_ΑΝ Κ='2' ΤΟΤΕ
        ΘΥ <-- ΘΥ+2
      ΤΕΛΟΣ_ΑΝ
      ΑΝ ΘΧ>27 ΤΟΤΕ
        ΘΧ <-- 3
      ΑΛΛΙΩΣ_ΑΝ ΘΧ<3 ΤΟΤΕ
        ΘΧ <-- 27
      ΤΕΛΟΣ_ΑΝ
      ΑΝ ΘΥ>18 ΤΟΤΕ
        ΘΥ <-- 2
      ΑΛΛΙΩΣ_ΑΝ ΘΥ<2 ΤΟΤΕ
        ΘΥ <-- 18
      ΤΕΛΟΣ_ΑΝ
      ΠΗΓΑΙΝΕ_ΧΥ ΘΧ,ΘΥ
    ΜΕΧΡΙΣ_ΟΤΟΥ Κ='5' Η Κ='0'
    ΑΝ Κ='5' ΤΟΤΕ
      ΔΙΑΒΑΣΕ ΑΡ
      Χ <-- Α_Μ(ΘΧ/3)
      Υ <-- Α_Μ(ΘΥ/2)
      ΣΟΥ[Χ+(Υ-1)*9] <-- ΑΡ
      ΑΝ ΑΡ<>0 ΤΟΤΕ
        ΑΝ ΑΠΟΔΕΚΤΟ(ΣΟΥ,Χ+(Υ-1)*9)=ΨΕΥΔΗΣ ΤΟΤΕ
          ΣΟΥ[Χ+(Υ-1)*9] <-- 0
          ΠΗΓΑΙΝΕ_ΧΥ ΘΧ-1,ΘΥ
          ΓΡΑΨΕ ' '
        ΑΛΛΙΩΣ
          ΠΙΑΣΜΕΝΕΣ[Χ+(Υ-1)*9] <-- ΑΛΗΘΗΣ
        ΤΕΛΟΣ_ΑΝ
      ΑΛΛΙΩΣ
        ΠΙΑΣΜΕΝΕΣ[Χ+(Υ-1)*9] <-- ΨΕΥΔΗΣ
        ΠΗΓΑΙΝΕ_ΧΥ ΘΧ-1,ΘΥ
        ΓΡΑΨΕ ' '
      ΤΕΛΟΣ_ΑΝ
    ΤΕΛΟΣ_ΑΝ
  ΜΕΧΡΙΣ_ΟΤΟΥ Κ='0'
  ΚΑΘΑΡΙΣΕ_ΟΘΟΝΗ
ΤΕΛΟΣ_ΔΙΑΔΙΚΑΣΙΑΣ


Μπορειτε να κατεβασετε και το exe :)
 

Σημείωση: Το μήνυμα αυτό γράφτηκε 15 χρόνια πριν. Ο συντάκτης του πιθανόν να έχει αλλάξει απόψεις έκτοτε.

Συνημμένα

  • Sudoku.exe
    42.5 KB · Εμφανίσεις: 181

Panos_K

Νεοφερμένος

Ο Παναγιωτης αυτή τη στιγμή δεν είναι συνδεδεμένος. Είναι 33 ετών, Φοιτητής και μας γράφει απο Πέλλα (Πέλλα). Έχει γράψει 4 μηνύματα.
Το προγραμμα λεξαριθμων:)

Code:
ΠΡΟΓΡΑΜΜΑ ΛΕΞΑΡΙΘΜΟΙ
ΜΕΤΑΒΛΗΤΕΣ
  ΧΑΡΑΚΤΗΡΕΣ:Χ
  ΑΚΕΡΑΙΕΣ:Α,Β,Ι,Κ
  ΛΟΓΙΚΕΣ:ΛΑΘΟΣ,ΑΛΛΑΓΗ,ΥΠ
  ΑΡΧΕΙΑ ΧΑΡΑΚΤΗΡΩΝ: ΚΑΤ
ΑΡΧΗ
  ΑΛΛΑΓΗ <-- ΨΕΥΔΗΣ
  ΣΥΣΧΕΤΙΣΕ_ΑΡΧΕΙΟ ΚΑΤ,'C:NumW.gm'
  ΑΝ ΥΠΑΡΧΕΙ_ΑΡΧΕΙΟ('C:NumW.gm')=ΨΕΥΔΗΣ ΤΟΤΕ
    ΔΗΜΙΟΥΡΓΗΣΕ_ΑΡΧΕΙΟ ΚΑΤ
    ΚΛΕΙΣΕ_ΑΡΧΕΙΟ ΚΑΤ
  ΤΕΛΟΣ_ΑΝ
  ΑΝΟΙΞΕ_ΑΡΧΕΙΟ ΚΑΤ
  ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
    Ι <-- ΜΕΓΕΘΟΣ_ΑΡΧΕΙΟΥ(ΚΑΤ)
    ΓΡΑΨΕ 'Ως τωρα:',Ι,'καταχωρημενες λεξεις/φρασεις'
    ΓΡΑΨΕ '<Enter> για μενου'
    ΑΝ  Ι=0 ΤΟΤΕ
      ΓΡΑΨΕ '**************************************************************'
      ΓΡΑΨΕ '!!Το μηνυμα θα σταματησει να εμφανιζεται οταν δωθει εγκυρη'
      ΓΡΑΨΕ 'εισοδος!!'
      ΓΡΑΨΕ '**************************************************************'
      ΓΡΑΨΕ 'Το πρόγραμμα δεχεται σαν εισοδο λεξεις η φρασεις.'
      ΓΡΑΨΕ 'Εμφανιζει σε ποιον αριθμο αντιστοιχουν.'
      ΓΡΑΨΕ 'Θα πρεπει να αποτελουνται μονο απο ΕΛΛΗΝΙΚΑ γραμματα.'
      ΓΡΑΨΕ 'Αποδεκτος χαρακτήρας ειναι και το <κενο>'
      ΓΡΑΨΕ 'Σε αντιθετη περίπτωση θα εμφανιζεται καταλληλο μηνυμα.'
      ΓΡΑΨΕ 'Μετα από καθε εξοδο θα γινεται ταξινομηση των λεξεων/φρασεων'
      ΓΡΑΨΕ '**************************************************************'
      ΓΡΑΨΕ '!!Για να γινεται ταξινομηση θα πρεπει η έξοδος να γινεται μεσω'
      ΓΡΑΨΕ 'του προγραμματος και να εχει δωθει καποια καινουρια λεξη/φραση!!'
      ΓΡΑΨΕ '**************************************************************'
    ΤΕΛΟΣ_ΑΝ
    ΓΡΑΨΕ_ 'Αντιστοιχιση του:'
    ΔΙΑΒΑΣΕ Χ
    Χ <-- Μ_Κ(Χ)
    ΚΑΛΕΣΕ ΛΕΞΑ(Χ,ΛΑΘΟΣ,Α)
    ΑΝ ΛΑΘΟΣ=ΨΕΥΔΗΣ ΤΟΤΕ
      ΥΠ <-- ΥΠΑΡΧΕΙ(Χ)
      ΑΝ ΥΠ=ΨΕΥΔΗΣ ΤΟΤΕ
        ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΚΑΤ,ΜΕΓΕΘΟΣ_ΑΡΧΕΙΟΥ(ΚΑΤ)+1
        ΓΡΑΨΕ_ΑΡΧΕΙΟ ΚΑΤ,Χ
        ΑΛΛΑΓΗ <-- ΑΛΗΘΗΣ                      
        ΓΡΑΨΕ 'Νεα λεξη/φραση !'
      ΤΕΛΟΣ_ΑΝ
      ΓΡΑΨΕ ' '
      ΓΡΑΨΕ '=======>--'
      ΓΡΑΨΕ 'Η παραπανω λεξη/φραση αντιστοιχει στον αριθμο:',Α
      ΓΡΑΨΕ '=======>--'
      ΓΡΑΨΕ_ 'Ομοιες λεξεις/φρασεις:'
      ΚΑΛΕΣΕ ΟΜΟΙΕΣ(Α,Χ)
    ΑΛΛΙΩΣ
      ΑΝ Χ<>'' ΤΟΤΕ
        ΓΡΑΨΕ '!Λανθασμενη εισοδος δεδομενων!'
      ΤΕΛΟΣ_ΑΝ
    ΤΕΛΟΣ_ΑΝ
    ΓΡΑΨΕ ' '
    ΓΡΑΨΕ '**********************************'
    ΓΡΑΨΕ '<Enter>. Εκτελεση ξανα'
    ΓΡΑΨΕ '2. Προβολη καταχωρημενων λεξεων/φρασεων'
    ΓΡΑΨΕ '3. Εξοδος'
    ΓΡΑΨΕ '4. Αναζητηση αριθμου'
    ΓΡΑΨΕ '5. Αναζητηση λεξης/φρασης'
    ΓΡΑΨΕ '6. Διαγραφη λεξης/φρασης'
    ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
      ΔΙΑΒΑΣΕ Χ
    ΜΕΧΡΙΣ_ΟΤΟΥ Χ='2' Η X='3' Η X='' Η Χ='4'  Η Χ='5'  Η Χ='6'
    ΑΝ Χ='2' ΤΟΤΕ
      ΚΑΛΕΣΕ ΠΡΟΒΟΛΗ
    ΑΛΛΙΩΣ_ΑΝ Χ='4' ΤΟΤΕ
      ΚΑΛΕΣΕ ΑΝ_ΑΡ
    ΑΛΛΙΩΣ_ΑΝ Χ='6' ΤΟΤΕ
      ΚΑΛΕΣΕ ΔΙΑΓ
    ΑΛΛΙΩΣ_ΑΝ Χ='5' ΤΟΤΕ
      ΚΑΛΕΣΕ ΑΝ_ΛΕΞ
    ΤΕΛΟΣ_ΑΝ
    ΚΑΘΑΡΙΣΕ_ΟΘΟΝΗ
  ΜΕΧΡΙΣ_ΟΤΟΥ Χ='3'
  ΑΝ ΑΛΛΑΓΗ=ΑΛΗΘΗΣ ΤΟΤΕ
    ΚΑΘΑΡΙΣΕ_ΟΘΟΝΗ
    ΓΡΑΨΕ 'Γινεται ταξινομηση'
    ΓΡΑΨΕ 'Ισως χαθουν δεδομενα εαν διακοπει'
    ΚΑΛΕΣΕ ΤΑΞΙΝ
  ΤΕΛΟΣ_ΑΝ
  ΚΛΕΙΣΕ_ΑΡΧΕΙΟ ΚΑΤ
  ΚΛΕΙΣΕ_ΠΑΡΑΘΥΡΟ
ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ
 
ΔΙΑΔΙΚΑΣΙΑ ΟΜΟΙΕΣ(Α,Χ)
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ:Α,ΜΑΧ,Φ
  ΧΑΡΑΚΤΗΡΕΣ:Χ,Π
ΑΡΧΗ
  Φ <-- 0
  ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΚΑΤ,1
  ΜΑΧ <-- ΜΕΓΕΘΟΣ_ΑΡΧΕΙΟΥ (ΚΑΤ)
  ΓΙΑ Ι ΑΠΟ 1 ΜΕΧΡΙ ΜΑΧ
    ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ ΚΑΤ,Π
    ΑΝ  ΣΥΝΤΟΜΗ(Π)=Α ΚΑΙ Χ<>Π ΤΟΤΕ
      Φ <-- Φ+1
      ΑΝ Φ<>1 ΤΟΤΕ
        ΓΡΑΨΕ_ ', '+Π
      ΑΛΛΙΩΣ
        ΓΡΑΨΕ_ Π
      ΤΕΛΟΣ_ΑΝ
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΑΝ Φ=0 ΤΟΤΕ
    ΓΡΑΨΕ_ 'Δεν υπαρχει καμια ομοια καταχωρημενη ως τωρα'
  ΤΕΛΟΣ_ΑΝ
  ΓΡΑΨΕ
  ΓΡΑΨΕ '=======>--'
ΤΕΛΟΣ_ΔΙΑΔΙΚΑΣΙΑΣ
 
ΣΥΝΑΡΤΗΣΗ ΥΠΑΡΧΕΙ(Χ):ΛΟΓΙΚΗ
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ:Ι,ΜΑΧ
  ΧΑΡΑΚΤΗΡΕΣ:Χ,Π
  ΛΟΓΙΚΕΣ:Λ
ΑΡΧΗ
  Λ <-- ΨΕΥΔΗΣ
  ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΚΑΤ,1
  ΜΑΧ <-- ΜΕΓΕΘΟΣ_ΑΡΧΕΙΟΥ (ΚΑΤ)
  ΑΝ ΜΑΧ>=1 ΤΟΤΕ
    Ι <-- 0
    ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
      Ι <-- Ι+1
      ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ ΚΑΤ,Π
      ΑΝ Π=Χ ΤΟΤΕ
        Λ <-- ΑΛΗΘΗΣ
      ΤΕΛΟΣ_ΑΝ
    ΜΕΧΡΙΣ_ΟΤΟΥ Ι=ΜΑΧ Η Λ=ΑΛΗΘΗΣ
  ΤΕΛΟΣ_ΑΝ
  ΥΠΑΡΧΕΙ <-- Λ
ΤΕΛΟΣ_ΣΥΝΑΡΤΗΣΗΣ
 
ΣΥΝΑΡΤΗΣΗ ΣΥΝΤΟΜΗ(Π):ΑΚΕΡΑΙΑ
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ:Ι,Α,Β,Κ
  ΧΑΡΑΚΤΗΡΕΣ:Π
ΑΡΧΗ
  Ι <-- ΜΗΚΟΣ_ΧΑΡ(Π)
  Α <-- 0
  Κ <-- 0
  ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
    Κ <-- Κ+1
    Β <-- ΑΡΙΘ(Π,Κ)
    Α <-- Α+Β
  ΜΕΧΡΙΣ_ΟΤΟΥ Κ=Ι
  ΣΥΝΤΟΜΗ <-- Α
ΤΕΛΟΣ_ΣΥΝΑΡΤΗΣΗΣ
 
ΔΙΑΔΙΚΑΣΙΑ ΛΕΞΑ(Χ,ΛΑΘΟΣ,Α)
ΜΕΤΑΒΛΗΤΕΣ
  ΛΟΓΙΚΕΣ:ΛΑΘΟΣ
  ΑΚΕΡΑΙΕΣ:Ι,Α,Β,Κ
  ΧΑΡΑΚΤΗΡΕΣ:Χ
ΑΡΧΗ
  ΛΑΘΟΣ <-- ΨΕΥΔΗΣ
  Ι <-- ΜΗΚΟΣ_ΧΑΡ(Χ)
  Α <-- 0
  Κ <-- 0
  ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
    Κ <-- Κ+1
    Β <-- ΑΡΙΘ(Χ,Κ)
    Α <-- Α+Β
    ΑΝ Β=-1 ΤΟΤΕ
      ΛΑΘΟΣ <-- ΑΛΗΘΗΣ
    ΤΕΛΟΣ_ΑΝ
  ΜΕΧΡΙΣ_ΟΤΟΥ Κ=Ι Η ΛΑΘΟΣ=ΑΛΗΘΗΣ
  ΑΝ Α=0 ΤΟΤΕ
    ΛΑΘΟΣ <-- ΑΛΗΘΗΣ
  ΤΕΛΟΣ_ΑΝ
ΤΕΛΟΣ_ΔΙΑΔΙΚΑΣΙΑΣ
 
ΣΥΝΑΡΤΗΣΗ ΑΡΙΘ(Χ,Κ):ΑΚΕΡΑΙΑ
ΜΕΤΑΒΛΗΤΕΣ
  ΧΑΡΑΚΤΗΡΕΣ:Χ
  ΑΚΕΡΑΙΕΣ:Π,Κ
ΑΡΧΗ
  ΑΝ Χ[Κ]='Α' ΤΟΤΕ
    Π <-- 1
  ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='Β' ΤΟΤΕ
    Π <-- 2
  ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='Γ' ΤΟΤΕ
    Π <-- 3
  ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='Δ' ΤΟΤΕ
    Π <-- 4
  ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='Ε' ΤΟΤΕ
    Π <-- 5
  ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='Ζ' ΤΟΤΕ
    Π <-- 7
  ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='Η' ΤΟΤΕ
    Π <-- 8
  ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='Θ' ΤΟΤΕ
    Π <-- 9
  ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='Ι' ΤΟΤΕ
    Π <-- 10
  ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='Κ' ΤΟΤΕ
    Π <-- 20
  ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='Λ' ΤΟΤΕ
    Π <-- 30
  ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='Μ' ΤΟΤΕ
    Π <-- 40
  ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='Ν' ΤΟΤΕ
    Π <-- 50
  ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='Ξ' ΤΟΤΕ
    Π <-- 60
  ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='Ο' ΤΟΤΕ
    Π <-- 70
  ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='Π' ΤΟΤΕ
    Π <-- 80
  ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='Ρ' ΤΟΤΕ
    Π <-- 100
  ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='Σ' ΤΟΤΕ
    Π <-- 200
  ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='Τ' ΤΟΤΕ
    Π <-- 300
  ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='Υ' ΤΟΤΕ
    Π <-- 400
  ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='Φ' ΤΟΤΕ
    Π <-- 500
  ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='Χ' ΤΟΤΕ
    Π <-- 600
  ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='Ψ' ΤΟΤΕ
    Π <-- 700
  ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='Ω' ΤΟΤΕ
    Π <-- 800
  ΑΛΛΙΩΣ_ΑΝ Χ[Κ]=' ' ΤΟΤΕ
    Π <-- 0
  ΑΛΛΙΩΣ
    Π <-- -1
  ΤΕΛΟΣ_ΑΝ
  ΑΡΙΘ <-- Π
ΤΕΛΟΣ_ΣΥΝΑΡΤΗΣΗΣ
 
ΔΙΑΔΙΚΑΣΙΑ ΠΡΟΒΟΛΗ
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ:Ι,ΜΑΧ,Μ,Α,ΣΕΙΡΑ
  ΧΑΡΑΚΤΗΡΕΣ:Χ,ΑΡΧ,ΕΠ
ΑΡΧΗ
  ΚΑΘΑΡΙΣΕ_ΟΘΟΝΗ
  ΜΑΧ <-- ΜΕΓΕΘΟΣ_ΑΡΧΕΙΟΥ (ΚΑΤ)
  ΑΝ ΜΑΧ>=1 ΤΟΤΕ
    ΓΡΑΨΕ '1.Προβολη ολων'
    ΓΡΑΨΕ '2.Επιλεκτικη προβολη'
    ΓΡΑΨΕ '3.Εξοδος'
    ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
      ΔΙΑΒΑΣΕ Χ
    ΜΕΧΡΙΣ_ΟΤΟΥ Χ='1' Η Χ='2' Η Χ='3'
    ΚΑΘΑΡΙΣΕ_ΟΘΟΝΗ
    ΑΝ Χ='1' ΤΟΤΕ
      ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΚΑΤ,1
      Ι <-- 0
      Μ <-- 0
      ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
        Ι <-- Ι+1
        ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ ΚΑΤ,Χ
        Α <-- ΣΥΝΤΟΜΗ(Χ)
        ΓΡΑΨΕ Ι,'.',Χ,'--->',Α
        Μ <-- Μ+1
        ΑΝ Μ=21 ΤΟΤΕ
          ΓΡΑΨΕ '=========================='
          ΓΡΑΨΕ '<Enter>. Συνεχεια προβολης'
          ΓΡΑΨΕ '3. Τερματισμος προβολης'
          ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
            ΔΙΑΒΑΣΕ Χ
          ΜΕΧΡΙΣ_ΟΤΟΥ Χ='' Η Χ='3'
          ΚΑΘΑΡΙΣΕ_ΟΘΟΝΗ
          Μ <-- 0
        ΤΕΛΟΣ_ΑΝ
      ΜΕΧΡΙΣ_ΟΤΟΥ Ι=ΜΑΧ Η Χ='3'
    ΑΛΛΙΩΣ_ΑΝ Χ='2' ΤΟΤΕ
      ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
        ΓΡΑΨΕ_ 'Προβολη λεξεων/φρασεων που αρχιζουν από (γραμμα):'
        ΔΙΑΒΑΣΕ ΑΡΧ
        ΑΡΧ <-- Μ_Κ(ΑΡΧ)
        ΚΑΘΑΡΙΣΕ_ΟΘΟΝΗ
      ΜΕΧΡΙΣ_ΟΤΟΥ ΜΗΚΟΣ_ΧΑΡ(ΑΡΧ)=1 ΚΑΙ ΑΡΙΘ(ΑΡΧ,1)>=0
      ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΚΑΤ,1
      Ι <-- 0
      Μ <-- 0
      ΣΕΙΡΑ <-- 0
      ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
        Ι <-- Ι+1
        ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ ΚΑΤ,Χ
        ΑΝ ΑΡΧ=Χ[1] ΤΟΤΕ
          ΣΕΙΡΑ <-- ΣΕΙΡΑ+1
          Α <-- ΣΥΝΤΟΜΗ(Χ)
          ΓΡΑΨΕ ΣΕΙΡΑ,'.',Χ,'--->',Α
          Μ <-- Μ+1
        ΤΕΛΟΣ_ΑΝ
        ΑΝ Μ=21 ΤΟΤΕ
          ΓΡΑΨΕ '=========================='
          ΓΡΑΨΕ '<Enter>. Συνεχεια προβολης'
          ΓΡΑΨΕ '3. Τερματισμος προβολης'
          ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
            ΔΙΑΒΑΣΕ ΕΠ
          ΜΕΧΡΙΣ_ΟΤΟΥ ΕΠ='' Η ΕΠ='3' Η Χ[1]>ΑΡΧ
          ΚΑΘΑΡΙΣΕ_ΟΘΟΝΗ
          Μ <-- 0
        ΤΕΛΟΣ_ΑΝ
      ΜΕΧΡΙΣ_ΟΤΟΥ Ι=ΜΑΧ Η ΕΠ='3' Η Χ[1]>ΑΡΧ
      ΑΝ ΣΕΙΡΑ=0 ΤΟΤΕ
        ΓΡΑΨΕ 'Καμια λεξη/φραση δεν αρχιζει απο:',ΑΡΧ
      ΤΕΛΟΣ_ΑΝ
    ΤΕΛΟΣ_ΑΝ
    ΓΡΑΨΕ '============================================'
    ΓΡΑΨΕ 'Η εμφανιση ολοκληρωθηκε,<Enter> για συνεχεια'
    ΔΙΑΒΑΣΕ Χ
  ΑΛΛΙΩΣ
    ΓΡΑΨΕ 'Δεν υπαρχουν καταχωρημενες λεξεις/φρασεις'
    ΓΡΑΨΕ '<Enter> για συνεχεια'
    ΔΙΑΒΑΣΕ Χ
  ΤΕΛΟΣ_ΑΝ
ΤΕΛΟΣ_ΔΙΑΔΙΚΑΣΙΑΣ
 
 
ΔΙΑΔΙΚΑΣΙΑ ΑΝ_ΑΡ
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ:Μ,Ι,ΜΑΧ,Α,Φ,ΣΕΙΡΑ,Μ2
  ΧΑΡΑΚΤΗΡΕΣ:Χ,ΛΕΙ
  ΛΟΓΙΚΕΣ:ΥΠ
ΑΡΧΗ
  ΜΑΧ <-- ΜΕΓΕΘΟΣ_ΑΡΧΕΙΟΥ(ΚΑΤ)
  ΑΝ ΜΑΧ>=1 ΤΟΤΕ
    ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
      ΚΑΘΑΡΙΣΕ_ΟΘΟΝΗ
      ΓΡΑΨΕ '1. Ευρεση ='
      ΓΡΑΨΕ '2. Ευρεση >='
      ΓΡΑΨΕ '3. Ευρεση <='
      ΓΡΑΨΕ '4. Ευρεση >= και <='
      ΓΡΑΨΕ '5. Εξοδος'
      ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
        ΔΙΑΒΑΣΕ ΛΕΙ
      ΜΕΧΡΙΣ_ΟΤΟΥ ΛΕΙ='1' Η ΛΕΙ='2' Η ΛΕΙ='3' Η ΛΕΙ='4' Η ΛΕΙ='5'
      ΑΝ ΛΕΙ<>'5' ΤΟΤΕ
        ΓΡΑΨΕ_ 'Αριθμος:'
        ΔΙΑΒΑΣΕ Μ
        ΑΝ  ΛΕΙ='4' ΤΟΤΕ
          ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
            ΓΡΑΨΕ_ 'Αριθμος 2 (>=',Μ,'):'
            ΔΙΑΒΑΣΕ Μ2
          ΜΕΧΡΙΣ_ΟΤΟΥ Μ2>=Μ
        ΤΕΛΟΣ_ΑΝ
        ΣΕΙΡΑ <-- 0
        ΥΠ <-- ΨΕΥΔΗΣ
        ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΚΑΤ,1
        ΚΑΘΑΡΙΣΕ_ΟΘΟΝΗ
        ΓΡΑΨΕ 'Οι παρακατω λεξεις/φρασεις ικανοποιουν τα κρητηρια'
        Ι <-- 0
        Φ <-- 0
        ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
          Ι <-- Ι+1
          ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ ΚΑΤ,Χ
          Α <-- ΣΥΝΤΟΜΗ(Χ)
          ΑΝ ΛΕΙ='1' ΤΟΤΕ
            ΑΝ Α=Μ ΤΟΤΕ
              ΥΠ <-- ΑΛΗΘΗΣ
              ΣΕΙΡΑ <-- ΣΕΙΡΑ+1
              Φ <-- Φ+1
              ΓΡΑΨΕ ΣΕΙΡΑ,'.', Χ
            ΤΕΛΟΣ_ΑΝ
          ΑΛΛΙΩΣ_ΑΝ ΛΕΙ='2' ΤΟΤΕ
            ΑΝ Α>=Μ ΤΟΤΕ
              ΥΠ <-- ΑΛΗΘΗΣ
              Φ <-- Φ+1
              ΣΕΙΡΑ <-- ΣΕΙΡΑ+1
              ΓΡΑΨΕ ΣΕΙΡΑ,'.',Χ,'-->',Α
            ΤΕΛΟΣ_ΑΝ
          ΑΛΛΙΩΣ_ΑΝ ΛΕΙ='3' ΤΟΤΕ
            ΑΝ Α<=Μ ΤΟΤΕ
              ΥΠ <-- ΑΛΗΘΗΣ
              Φ <-- Φ+1
              ΣΕΙΡΑ <-- ΣΕΙΡΑ+1
              ΓΡΑΨΕ ΣΕΙΡΑ,'.',Χ,'-->',Α
            ΤΕΛΟΣ_ΑΝ
          ΑΛΛΙΩΣ_ΑΝ ΛΕΙ='4' ΤΟΤΕ
            ΑΝ Α>=Μ ΚΑΙ Α<=Μ2 ΤΟΤΕ
              ΥΠ <-- ΑΛΗΘΗΣ
              Φ <-- Φ+1
              ΣΕΙΡΑ <-- ΣΕΙΡΑ+1
              ΓΡΑΨΕ ΣΕΙΡΑ,'.',Χ,'-->',Α
            ΤΕΛΟΣ_ΑΝ
          ΤΕΛΟΣ_ΑΝ
          ΑΝ Φ=19 ΤΟΤΕ
            Φ <-- 0
            ΓΡΑΨΕ '=========================='
            ΓΡΑΨΕ '<Enter>. Συνεχεια αναζητησης'
            ΓΡΑΨΕ '3. Τερματισμος αναζητησης'
            ΔΙΑΒΑΣΕ Χ
            ΚΑΘΑΡΙΣΕ_ΟΘΟΝΗ
          ΤΕΛΟΣ_ΑΝ
        ΜΕΧΡΙΣ_ΟΤΟΥ Ι=ΜΑΧ Η Χ='3'
        ΑΝ ΥΠ=ΨΕΥΔΗΣ ΤΟΤΕ
          ΓΡΑΨΕ 'Καμια λεξη/φραση δεν ικανοποιει τα κρητηρια'
        ΤΕΛΟΣ_ΑΝ
        ΓΡΑΨΕ '========================'
        ΓΡΑΨΕ 'Η αναζητηση ολοκληρωθηκε'
        ΓΡΑΨΕ '<Enter>. για επαναληψη'
        ΓΡΑΨΕ '3. Επιστροφη στην κανονικη λειτουργεια'
        ΔΙΑΒΑΣΕ Χ
      ΤΕΛΟΣ_ΑΝ
    ΜΕΧΡΙΣ_ΟΤΟΥ Χ='3' Η ΛΕΙ='5'
  ΤΕΛΟΣ_ΑΝ
ΤΕΛΟΣ_ΔΙΑΔΙΚΑΣΙΑΣ
 
ΔΙΑΔΙΚΑΣΙΑ ΔΙΑΓ
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ:Ι,ΜΑΧ,Θ
  ΧΑΡΑΚΤΗΡΕΣ:Χ
ΑΡΧΗ
  ΚΑΘΑΡΙΣΕ_ΟΘΟΝΗ
  ΜΑΧ <-- ΜΕΓΕΘΟΣ_ΑΡΧΕΙΟΥ (ΚΑΤ)
  ΑΝ ΜΑΧ>=1 ΤΟΤΕ
    ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
      ΚΑΘΑΡΙΣΕ_ΟΘΟΝΗ
      ΓΡΑΨΕ 'Δωσε αριθμο καταχωρησης (μεγιστο',ΜΑΧ,'):'
      ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
        ΔΙΑΒΑΣΕ Θ
      ΜΕΧΡΙΣ_ΟΤΟΥ Θ>=1 ΚΑΙ Θ<=ΜΑΧ
      ΚΑΘΑΡΙΣΕ_ΟΘΟΝΗ
      ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΚΑΤ,Θ
      ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ ΚΑΤ,Χ
      ΓΡΑΨΕ 'Διαγραφη του: "',Χ,'" ?'
      ΓΡΑΨΕ '=======>--'
      ΓΡΑΨΕ '1.Οχι/Εξοδος'
      ΓΡΑΨΕ '2.Επιλογη αλλης'
      ΓΡΑΨΕ '6.Ναι'
      ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
        ΔΙΑΒΑΣΕ Χ
      ΜΕΧΡΙΣ_ΟΤΟΥ Χ='1' Η Χ='2' Η Χ='6'
    ΜΕΧΡΙΣ_ΟΤΟΥ Χ='1' Η Χ='6'
    ΑΝ Χ='6' ΤΟΤΕ
      ΓΙΑ Ι ΑΠΟ 1 ΜΕΧΡΙ ΜΑΧ-Θ
        ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΚΑΤ,Θ+Ι
        ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ ΚΑΤ,Χ
        ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΚΑΤ,Θ+Ι-1
        ΓΡΑΨΕ_ΑΡΧΕΙΟ ΚΑΤ,Χ
      ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
      ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΚΑΤ,ΜΑΧ
      ΑΠΟΚΟΨΕ_ΑΡΧΕΙΟ ΚΑΤ
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΑΝ
ΤΕΛΟΣ_ΔΙΑΔΙΚΑΣΙΑΣ
 
ΔΙΑΔΙΚΑΣΙΑ ΤΑΞΙΝ
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ:ΜΑΧ,Ι,Κ
  ΧΑΡΑΚΤΗΡΕΣ:Χ1,Χ2,Π
  ΛΟΓΙΚΕΣ:ΕΞΩ
ΑΡΧΗ
  ΜΑΧ <-- ΜΕΓΕΘΟΣ_ΑΡΧΕΙΟΥ (ΚΑΤ)
  ΑΝ ΜΑΧ>=2 ΤΟΤΕ
    ΠΗΓΑΙΝΕ_ΧΥ 1,5
    ΓΡΑΨΕ 'Ολοκληρωθηκε:'
    Ι <-- 1
    ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
      ΕΞΩ <-- ΑΛΗΘΗΣ
      Κ <-- ΜΑΧ
      ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
        ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΚΑΤ,Κ
        ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ ΚΑΤ,Χ2
        ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΚΑΤ,Κ-1
        ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ ΚΑΤ,Χ1
        ΑΝ Χ2<Χ1 ΤΟΤΕ
          ΕΞΩ <-- ΨΕΥΔΗΣ
          ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΚΑΤ,Κ
          ΓΡΑΨΕ_ΑΡΧΕΙΟ ΚΑΤ,Χ1
          ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΚΑΤ,Κ-1
          ΓΡΑΨΕ_ΑΡΧΕΙΟ ΚΑΤ,Χ2
        ΤΕΛΟΣ_ΑΝ
        Κ <-- Κ-1
      ΜΕΧΡΙΣ_ΟΤΟΥ Κ=1
      ΠΗΓΑΙΝΕ_ΧΥ 14,5
      ΓΡΑΨΕ (Ι/ΜΑΧ)*100,'%'
      Ι <-- Ι+1
    ΜΕΧΡΙΣ_ΟΤΟΥ Ι=ΜΑΧ  Η ΕΞΩ=ΑΛΗΘΗΣ
  ΤΕΛΟΣ_ΑΝ
ΤΕΛΟΣ_ΔΙΑΔΙΚΑΣΙΑΣ
 
ΔΙΑΔΙΚΑΣΙΑ ΑΝ_ΛΕΞ
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ:Ι,Θ,ΜΑΧ
  ΧΑΡΑΚΤΗΡΕΣ:ΑΡΧ,ΕΠ,Π
ΑΡΧΗ
  ΜΑΧ <-- ΜΕΓΕΘΟΣ_ΑΡΧΕΙΟΥ (ΚΑΤ)
  ΑΝ ΜΑΧ>=1 ΤΟΤΕ
    ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
      ΚΑΘΑΡΙΣΕ_ΟΘΟΝΗ
      ΓΡΑΨΕ_ 'Αναζητηση της λεξης/φρασης:'
      ΔΙΑΒΑΣΕ Π
      Π <-- Μ_Κ(Π)
      Ι <-- 0
      Θ <-- 0
      ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΚΑΤ,1
      ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
        Ι <-- Ι+1
        ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ ΚΑΤ,ΑΡΧ
        ΑΝ ΑΡΧ=Π ΤΟΤΕ
          Θ <-- Ι
        ΤΕΛΟΣ_ΑΝ
      ΜΕΧΡΙΣ_ΟΤΟΥ Ι=ΜΑΧ Η Θ<>0
      ΓΡΑΨΕ '=======>--'
      ΑΝ Θ<>0 ΤΟΤΕ
        ΓΡΑΨΕ 'Η λεξη/φραση βρισκεται στην θεση:',Θ
      ΑΛΛΙΩΣ
        ΓΡΑΨΕ 'Δεν βρεθηκε'
      ΤΕΛΟΣ_ΑΝ
      ΓΡΑΨΕ '=======>--'
      ΓΡΑΨΕ '1.Εξοδος'
      ΓΡΑΨΕ '<Enter>. Εκτελεση ξανα'
      ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
        ΔΙΑΒΑΣΕ ΕΠ
      ΜΕΧΡΙΣ_ΟΤΟΥ ΕΠ='1' Η ΕΠ=''
    ΜΕΧΡΙΣ_ΟΤΟΥ  ΕΠ='1'
  ΤΕΛΟΣ_ΑΝ
ΤΕΛΟΣ_ΔΙΑΔΙΚΑΣΙΑΣ
 
ΣΥΝΑΡΤΗΣΗ Μ_Κ(Χ):ΧΑΡΑΚΤΗΡΕΣ
ΜΕΤΑΒΛΗΤΕΣ
  ΧΑΡΑΚΤΗΡΕΣ:Χ,ΕΠ
  ΑΚΕΡΑΙΕΣ:ΜΑΧ,Κ
ΑΡΧΗ
  ΜΑΧ <-- ΜΗΚΟΣ_ΧΑΡ(Χ)
  ΓΙΑ Κ ΑΠΟ 1 ΜΕΧΡΙ ΜΑΧ
    ΑΝ Χ[Κ]='α' ΤΟΤΕ
      Χ[Κ] <-- 'Α'                                                         
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='β' ΤΟΤΕ
      Χ[Κ] <-- 'Β'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='γ' ΤΟΤΕ
      Χ[Κ] <-- 'Γ'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='δ' ΤΟΤΕ
      Χ[Κ] <-- 'Δ'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='ε' ΤΟΤΕ
      Χ[Κ] <-- 'Ε'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='ζ' ΤΟΤΕ
      Χ[Κ] <-- 'Ζ'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='η' ΤΟΤΕ
      Χ[Κ] <-- 'Η'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='θ' ΤΟΤΕ
      Χ[Κ] <-- 'Θ'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='ι' ΤΟΤΕ
      Χ[Κ] <-- 'Ι'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='κ' ΤΟΤΕ
      Χ[Κ] <-- 'Κ'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='λ' ΤΟΤΕ
      Χ[Κ] <-- 'Λ'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='μ' ΤΟΤΕ
      Χ[Κ] <-- 'Μ'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='ν' ΤΟΤΕ
      Χ[Κ] <-- 'Ν'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='ξ' ΤΟΤΕ
      Χ[Κ] <-- 'Ξ'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='ο' ΤΟΤΕ
      Χ[Κ] <-- 'Ο'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='π' ΤΟΤΕ
      Χ[Κ] <-- 'Π'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='ρ' ΤΟΤΕ
      Χ[Κ] <-- 'Ρ'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='σ' Η Χ[Κ]='ς' ΤΟΤΕ
      Χ[Κ] <-- 'Σ'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='τ' ΤΟΤΕ
      Χ[Κ] <-- 'Τ'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='υ' ΤΟΤΕ
      Χ[Κ] <-- 'Υ'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='φ' ΤΟΤΕ
      Χ[Κ] <-- 'Φ'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='χ' ΤΟΤΕ
      Χ[Κ] <-- 'Χ'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='ψ' ΤΟΤΕ
      Χ[Κ] <-- 'Ψ'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='ω' ΤΟΤΕ
      Χ[Κ] <-- 'Ω'
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  Μ_Κ <--  Χ
ΤΕΛΟΣ_ΣΥΝΑΡΤΗΣΗΣ


Κατεβαστε και το exe
 

Σημείωση: Το μήνυμα αυτό γράφτηκε 15 χρόνια πριν. Ο συντάκτης του πιθανόν να έχει αλλάξει απόψεις έκτοτε.

Συνημμένα

  • NumW2.exe
    51.5 KB · Εμφανίσεις: 167

cJay

Εκκολαπτόμενο μέλος

Ο Χρήστος αυτή τη στιγμή δεν είναι συνδεδεμένος. Είναι 32 ετών και Φοιτητής. Έχει γράψει 196 μηνύματα.
Να και ένα κομπιουτεράκι :P

Code:
ΠΡΟΓΡΑΜΜΑ ΚΟΜΠΙΟΥΤΕΡΑΚΙ
ΜΕΤΑΒΛΗΤΕΣ
  ΠΡΑΓΜΑΤΙΚΕΣ:Α,Β,Δ
  ΑΚΕΡΑΙΕΣ:Γ
ΑΡΧΗ
  ΓΡΑΨΕ 'ΠΙΕΣΤΕ 1 ΓΙΑ ΠΡΟΣΘΕΣΗ, 2 ΓΙΑ ΑΦΑΙΡΕΣΗ, 3 ΓΙΑ ΠΟΛΛΑΠΛΑΣΙΑΣΜΟ, 4 ΓΙΑ ΔΙΑΙΡΕΣΗ'
  ΔΙΑΒΑΣΕ Γ
  ΕΠΙΛΕΞΕ Γ
    ΠΕΡΙΠΤΩΣΗ 1
      ΓΡΑΨΕ 'ΔΩΣΕ ΤΟΝ 1ο ΚΑΙ ΜΕΤΑ ΤΟΝ 2ο'
      ΔΙΑΒΑΣΕ Α,Β
      Δ <-- Α+Β
      ΓΡΑΨΕ 'ΤΟ ΑΠΟΤΕΛΕΣΜΑ ΕΙΝΑΙ',Δ
    ΠΕΡΙΠΤΩΣΗ 2
      ΓΡΑΨΕ 'ΔΩΣΕ ΤΟΝ 1ο ΚΑΙ ΜΕΤΑ ΤΟΝ 2ο'
      ΔΙΑΒΑΣΕ Α,Β
      Δ <-- Α-Β
      ΓΡΑΨΕ 'ΤΟ ΑΠΟΤΕΛΕΣΜΑ ΕΙΝΑΙ',Δ
    ΠΕΡΙΠΤΩΣΗ 3
      ΓΡΑΨΕ 'ΔΩΣΕ ΤΟΝ 1ο ΚΑΙ ΜΕΤΑ ΤΟΝ 2ο'
      ΔΙΑΒΑΣΕ Α,Β
      Δ <-- Α*Β
      ΓΡΑΨΕ 'ΤΟ ΑΠΟΤΕΛΕΣΜΑ ΕΙΝΑΙ',Δ
    ΠΕΡΙΠΤΩΣΗ 4
      ΓΡΑΨΕ 'ΔΩΣΕ ΤΟΝ 1ο ΚΑΙ ΜΕΤΑ ΤΟΝ 2ο'
      ΔΙΑΒΑΣΕ Α,Β
      ΑΝ Β=0 ΤΟΤΕ
        ΓΡΑΨΕ 'Η ΕΞΙΣΩΣΗ ΔΕΝ ΟΡΙΖΕΤΑΙ'
      ΑΛΛΙΩΣ
        Δ <-- Α/Β
        ΓΡΑΨΕ 'ΤΟ ΑΠΟΤΕΛΕΣΜΑ ΕΙΝΑΙ',Δ
      ΤΕΛΟΣ_ΑΝ
    ΠΕΡΙΠΤΩΣΗ ΑΛΛΙΩΣ
      ΓΡΑΨΕ 'ΤΡΟΜΠΑΣ ΕΙΣΑΙ?! ΑΠΟ ΤΟ 1 ΜΕΧΡΙ ΤΟ 4 ΕΙΠΑΜΕ...ΕΛΕΟΣ ΕΙΣΑΙ ΑΔΕΡΦΕ ΜΟΥ :S'
      ΓΡΑΨΕ 'ΠΙΕΣΕ 1 ΓΙΑ ΠΡΟΣΘΕΣΗ, 2 ΓΙΑ ΑΦΑΙΡΕΣΗ, 3 ΓΙΑ ΠΟΛΛΑΠΛΑΣΙΑΣΜΟ, 4 ΓΙΑ ΔΙΑΙΡΕΣΗ'
      ΔΙΑΒΑΣΕ Γ
      ΕΠΙΛΕΞΕ Γ
        ΠΕΡΙΠΤΩΣΗ 1
          ΓΡΑΨΕ 'ΔΩΣΕ ΤΟΝ 1ο ΚΑΙ ΜΕΤΑ ΤΟΝ 2ο'
          ΔΙΑΒΑΣΕ Α,Β
          Δ <-- Α+Β
          ΓΡΑΨΕ 'ΤΟ ΑΠΟΤΕΛΕΣΜΑ ΕΙΝΑΙ',Δ
        ΠΕΡΙΠΤΩΣΗ 2
          ΓΡΑΨΕ 'ΔΩΣΕ ΤΟΝ 1ο ΚΑΙ ΜΕΤΑ ΤΟΝ 2ο'
          ΔΙΑΒΑΣΕ Α,Β
          Δ <-- Α-Β
          ΓΡΑΨΕ 'ΤΟ ΑΠΟΤΕΛΕΣΜΑ ΕΙΝΑΙ',Δ
        ΠΕΡΙΠΤΩΣΗ 3
          ΓΡΑΨΕ 'ΔΩΣΕ ΤΟΝ 1ο ΚΑΙ ΜΕΤΑ ΤΟΝ 2ο'
          ΔΙΑΒΑΣΕ Α,Β
          Δ <-- Α*Β
          ΓΡΑΨΕ 'ΤΟ ΑΠΟΤΕΛΕΣΜΑ ΕΙΝΑΙ',Δ
        ΠΕΡΙΠΤΩΣΗ 4
          ΓΡΑΨΕ 'ΔΩΣΕ ΤΟΝ 1ο ΚΑΙ ΜΕΤΑ ΤΟΝ 2ο'
          ΔΙΑΒΑΣΕ Α,Β
          ΑΝ Β=0 ΤΟΤΕ
            ΓΡΑΨΕ 'Η ΕΞΙΣΩΣΗ ΔΕΝ ΟΡΙΖΕΤΑΙ'
          ΑΛΛΙΩΣ
            Δ <-- Α/Β
            ΓΡΑΨΕ 'ΤΟ ΑΠΟΤΕΛΕΣΜΑ ΕΙΝΑΙ',Δ
          ΤΕΛΟΣ_ΑΝ
        ΠΕΡΙΠΤΩΣΗ ΑΛΛΙΩΣ
          ΓΡΑΨΕ 'ΑΑΑ...ΔΕΝ ΒΓΑΖΩ ΑΚΡΗ ΜΑΖΙ ΣΟΥ...ΠΑΡΑΤΑ ΜΕ ΤΩΡΑ ΝΕΥΡΙΑΣΑ...'
      ΤΕΛΟΣ_ΕΠΙΛΟΓΩΝ
  ΤΕΛΟΣ_ΕΠΙΛΟΓΩΝ
ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ ΚΟΜΠΙΟΥΤΕΡΑΚΙ
 

Σημείωση: Το μήνυμα αυτό γράφτηκε 15 χρόνια πριν. Ο συντάκτης του πιθανόν να έχει αλλάξει απόψεις έκτοτε.

Ιορδανης

Νεοφερμένος

Ο Ιορδανης αυτή τη στιγμή δεν είναι συνδεδεμένος. Είναι 33 ετών και Φοιτητής. Έχει γράψει 50 μηνύματα.
cJay μας δουλευεις ? εδω το παιδι κεντάει και εσυ μας ανεβαζεις προγραμματα της που τα κανει καποιος στην στιγμη?
:down::down::down::down:
:boom::boom::boom: :boom: :boom:
 

Σημείωση: Το μήνυμα αυτό γράφτηκε 15 χρόνια πριν. Ο συντάκτης του πιθανόν να έχει αλλάξει απόψεις έκτοτε.

who

Πολύ δραστήριο μέλος

Ο who αυτή τη στιγμή δεν είναι συνδεδεμένος. Είναι 36 ετών, Φοιτητής και μας γράφει απο Περιστέρι (Αττική). Έχει γράψει 1,616 μηνύματα.
cJay μας δουλευεις ? εδω το παιδι κεντάει και εσυ μας ανεβαζεις προγραμματα της που τα κανει καποιος στην στιγμη?
:down::down::down::down:
:boom::boom::boom: :boom: :boom:

Κακιούλες :)
 

Σημείωση: Το μήνυμα αυτό γράφτηκε 15 χρόνια πριν. Ο συντάκτης του πιθανόν να έχει αλλάξει απόψεις έκτοτε.

cJay

Εκκολαπτόμενο μέλος

Ο Χρήστος αυτή τη στιγμή δεν είναι συνδεδεμένος. Είναι 32 ετών και Φοιτητής. Έχει γράψει 196 μηνύματα.
Ο καθένας ότι μπορεί :thanks:
 

Σημείωση: Το μήνυμα αυτό γράφτηκε 15 χρόνια πριν. Ο συντάκτης του πιθανόν να έχει αλλάξει απόψεις έκτοτε.

apagal

Νεοφερμένος

Ο apagal αυτή τη στιγμή δεν είναι συνδεδεμένος. Είναι 33 ετών και Μαθητής Γ' λυκείου. Έχει γράψει 37 μηνύματα.
Παιδιά μπορούμε να κάνουμε το πρόγραμμα της γλωσσομάθειας .exe?
 

Σημείωση: Το μήνυμα αυτό γράφτηκε 15 χρόνια πριν. Ο συντάκτης του πιθανόν να έχει αλλάξει απόψεις έκτοτε.

EpaRon

Εκκολαπτόμενο μέλος

Ο Νώντας αυτή τη στιγμή δεν είναι συνδεδεμένος. Είναι Φοιτητής και μας γράφει απο Λευκάδα (Λευκάδα). Έχει γράψει 203 μηνύματα.
Ναι, χρησιμοποιόντας την έκδοση του Μεταγλωττιστή που βρίσκεις εδώ
 

Σημείωση: Το μήνυμα αυτό γράφτηκε 15 χρόνια πριν. Ο συντάκτης του πιθανόν να έχει αλλάξει απόψεις έκτοτε.

xanoumi

Νεοφερμένος

Ο xanoumi αυτή τη στιγμή δεν είναι συνδεδεμένος. Είναι 34 ετών, Φοιτητής και μας γράφει απο Αμπελόκηποι (Αττική). Έχει γράψει 6 μηνύματα.
Πολύ καλά τα προγραμματάκια μικρά και ωραία. Συγχαρητήρια
 

Σημείωση: Το μήνυμα αυτό γράφτηκε 15 χρόνια πριν. Ο συντάκτης του πιθανόν να έχει αλλάξει απόψεις έκτοτε.

akantou!

Νεοφερμένος

Η akantou! αυτή τη στιγμή δεν είναι συνδεδεμένη. Είναι 32 ετών και Μαθητής Γ' λυκείου. Έχει γράψει 8 μηνύματα.
εγω εχω κατεβασει την γλωσσομαθεια..πρεπει να κατεβασω και τπτ αλλο;θα μου χρειαστει;
 

Σημείωση: Το μήνυμα αυτό γράφτηκε 15 χρόνια πριν. Ο συντάκτης του πιθανόν να έχει αλλάξει απόψεις έκτοτε.

paparounas

Νεοφερμένος

Ο paparounas αυτή τη στιγμή δεν είναι συνδεδεμένος. Είναι Μαθητής Γ' λυκείου και μας γράφει απο Κερατσίνι (Αττική). Έχει γράψει 69 μηνύματα.
Θ ήθελα να ρωτήσω, αν ξέρει κανείς, πως μπορούμε να περάσουμε και να τρέξουμε τα "προγράμματά" που φτιάχνουμε στον υπολογιστή μας, με ποιο πρόγραμμα και με τι αντιστοιχούν τα ελληνικά σύμβολα με τα αντίστοιχα αγγλικά ή της γλώσσας που θα χρησιμοποιήσουμε.
Ευχαριστώ εκ των προτέρων...
 

Σημείωση: Το μήνυμα αυτό γράφτηκε 14 χρόνια πριν. Ο συντάκτης του πιθανόν να έχει αλλάξει απόψεις έκτοτε.

Evris7

Πολύ δραστήριο μέλος

Ο Evris7 αυτή τη στιγμή δεν είναι συνδεδεμένος. Είναι Απόφοιτος. Έχει γράψει 815 μηνύματα.
Μπορείς αυτά που κάνουμε στο ΑΕΠΠ να τα τρέξεις με τη γλωσσομάθεια.
Κατέβασε την από εδώ https://spinet.gr/glossomatheia/download/
 

Σημείωση: Το μήνυμα αυτό γράφτηκε 14 χρόνια πριν. Ο συντάκτης του πιθανόν να έχει αλλάξει απόψεις έκτοτε.

paparounas

Νεοφερμένος

Ο paparounas αυτή τη στιγμή δεν είναι συνδεδεμένος. Είναι Μαθητής Γ' λυκείου και μας γράφει απο Κερατσίνι (Αττική). Έχει γράψει 69 μηνύματα.
Ευχαριστώ φίλε μου. :)
 

Σημείωση: Το μήνυμα αυτό γράφτηκε 14 χρόνια πριν. Ο συντάκτης του πιθανόν να έχει αλλάξει απόψεις έκτοτε.

ptsiotakis

Εκκολαπτόμενο μέλος

Ο ptsiotakis αυτή τη στιγμή δεν είναι συνδεδεμένος. Έχει γράψει 271 μηνύματα.
Δε χρειάζεται καν να είναι πρόγραμμα

Δείτε το www.pseudoglossa.gr
 

Σημείωση: Το μήνυμα αυτό γράφτηκε 14 χρόνια πριν. Ο συντάκτης του πιθανόν να έχει αλλάξει απόψεις έκτοτε.

just_rock

Νεοφερμένος

Η Βάσω αυτή τη στιγμή δεν είναι συνδεδεμένη. Είναι 31 ετών, Μαθητής Γ' λυκείου και μας γράφει απο Ρέθυμνο (Ρέθυμνο). Έχει γράψει 77 μηνύματα.
Δε χρειάζεται καν να είναι πρόγραμμα

Δείτε το www.pseudoglossa.gr

μπηκα σε αυτην την σελιδα αλλα μετα που εκτελω τον αλγοριθμο μου βγαζει μια κιτρινη γραμμη και στο πλαι τις μεταβλητες...τι πρεπει να κανω???
 

Σημείωση: Το μήνυμα αυτό γράφτηκε 14 χρόνια πριν. Ο συντάκτης του πιθανόν να έχει αλλάξει απόψεις έκτοτε.

ptsiotakis

Εκκολαπτόμενο μέλος

Ο ptsiotakis αυτή τη στιγμή δεν είναι συνδεδεμένος. Έχει γράψει 271 μηνύματα.
αν έχεις εντολές εισόδου, τότε περιμένει την πληκτρολόγηση τιμών (στο κάτω μέρος)
και βέβαια, έχει και βηματική εκτέλεση και τα σχετικά. θα δεις την έξοδο του αλγορίθμου επίσης στο κάτω μέρος του παραθύρου
 

Σημείωση: Το μήνυμα αυτό γράφτηκε 14 χρόνια πριν. Ο συντάκτης του πιθανόν να έχει αλλάξει απόψεις έκτοτε.

Evris7

Πολύ δραστήριο μέλος

Ο Evris7 αυτή τη στιγμή δεν είναι συνδεδεμένος. Είναι Απόφοιτος. Έχει γράψει 815 μηνύματα.
μπηκα σε αυτην την σελιδα αλλα μετα που εκτελω τον αλγοριθμο μου βγαζει μια κιτρινη γραμμη και στο πλαι τις μεταβλητες...τι πρεπει να κανω???

Πρέπει να ορίσεις τί μεταβλητές είναι (πχ ακέραιες, πραγματικές)
 

Σημείωση: Το μήνυμα αυτό γράφτηκε 14 χρόνια πριν. Ο συντάκτης του πιθανόν να έχει αλλάξει απόψεις έκτοτε.

ptsiotakis

Εκκολαπτόμενο μέλος

Ο ptsiotakis αυτή τη στιγμή δεν είναι συνδεδεμένος. Έχει γράψει 271 μηνύματα.
Στο www.pseudoglossa.gr του Στάθη Στεργίου

εκτελείται η ψευδογλώσσα, δεν απαιτείται η δήλωση μεταβλητών
 

Σημείωση: Το μήνυμα αυτό γράφτηκε 14 χρόνια πριν. Ο συντάκτης του πιθανόν να έχει αλλάξει απόψεις έκτοτε.

Χρήστες Βρείτε παρόμοια

  • Τα παρακάτω 0 μέλη και 1 επισκέπτες διαβάζουν μαζί με εσάς αυτό το θέμα:
    Tα παρακάτω 2 μέλη διάβασαν αυτό το θέμα:
  • Φορτώνει...
Top