Άλλα μηνύματα του μέλους Panos_K σε αυτό το thread

Panos_K · 10-09-08

Το προγραμμα λεξαριθμων

Code:

ΠΡΟΓΡΑΜΜΑ ΛΕΞΑΡΙΘΜΟΙ
ΜΕΤΑΒΛΗΤΕΣ
  ΧΑΡΑΚΤΗΡΕΣ:Χ
  ΑΚΕΡΑΙΕΣ:Α,Β,Ι,Κ
  ΛΟΓΙΚΕΣ:ΛΑΘΟΣ,ΑΛΛΑΓΗ,ΥΠ
  ΑΡΧΕΙΑ ΧΑΡΑΚΤΗΡΩΝ: ΚΑΤ
ΑΡΧΗ
  ΑΛΛΑΓΗ <-- ΨΕΥΔΗΣ
  ΣΥΣΧΕΤΙΣΕ_ΑΡΧΕΙΟ ΚΑΤ,'C:NumW.gm'
  ΑΝ ΥΠΑΡΧΕΙ_ΑΡΧΕΙΟ('C:NumW.gm')=ΨΕΥΔΗΣ ΤΟΤΕ
    ΔΗΜΙΟΥΡΓΗΣΕ_ΑΡΧΕΙΟ ΚΑΤ
    ΚΛΕΙΣΕ_ΑΡΧΕΙΟ ΚΑΤ
  ΤΕΛΟΣ_ΑΝ
  ΑΝΟΙΞΕ_ΑΡΧΕΙΟ ΚΑΤ
  ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
    Ι <-- ΜΕΓΕΘΟΣ_ΑΡΧΕΙΟΥ(ΚΑΤ)
    ΓΡΑΨΕ 'Ως τωρα:',Ι,'καταχωρημενες λεξεις/φρασεις'
    ΓΡΑΨΕ '<Enter> για μενου'
    ΑΝ  Ι=0 ΤΟΤΕ
      ΓΡΑΨΕ '**************************************************************'
      ΓΡΑΨΕ '!!Το μηνυμα θα σταματησει να εμφανιζεται οταν δωθει εγκυρη'
      ΓΡΑΨΕ 'εισοδος!!'
      ΓΡΑΨΕ '**************************************************************'
      ΓΡΑΨΕ 'Το πρόγραμμα δεχεται σαν εισοδο λεξεις η φρασεις.'
      ΓΡΑΨΕ 'Εμφανιζει σε ποιον αριθμο αντιστοιχουν.'
      ΓΡΑΨΕ 'Θα πρεπει να αποτελουνται μονο απο ΕΛΛΗΝΙΚΑ γραμματα.'
      ΓΡΑΨΕ 'Αποδεκτος χαρακτήρας ειναι και το <κενο>'
      ΓΡΑΨΕ 'Σε αντιθετη περίπτωση θα εμφανιζεται καταλληλο μηνυμα.'
      ΓΡΑΨΕ 'Μετα από καθε εξοδο θα γινεται ταξινομηση των λεξεων/φρασεων'
      ΓΡΑΨΕ '**************************************************************'
      ΓΡΑΨΕ '!!Για να γινεται ταξινομηση θα πρεπει η έξοδος να γινεται μεσω'
      ΓΡΑΨΕ 'του προγραμματος και να εχει δωθει καποια καινουρια λεξη/φραση!!'
      ΓΡΑΨΕ '**************************************************************'
    ΤΕΛΟΣ_ΑΝ
    ΓΡΑΨΕ_ 'Αντιστοιχιση του:'
    ΔΙΑΒΑΣΕ Χ
    Χ <-- Μ_Κ(Χ)
    ΚΑΛΕΣΕ ΛΕΞΑ(Χ,ΛΑΘΟΣ,Α)
    ΑΝ ΛΑΘΟΣ=ΨΕΥΔΗΣ ΤΟΤΕ
      ΥΠ <-- ΥΠΑΡΧΕΙ(Χ)
      ΑΝ ΥΠ=ΨΕΥΔΗΣ ΤΟΤΕ
        ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΚΑΤ,ΜΕΓΕΘΟΣ_ΑΡΧΕΙΟΥ(ΚΑΤ)+1
        ΓΡΑΨΕ_ΑΡΧΕΙΟ ΚΑΤ,Χ
        ΑΛΛΑΓΗ <-- ΑΛΗΘΗΣ                      
        ΓΡΑΨΕ 'Νεα λεξη/φραση !'
      ΤΕΛΟΣ_ΑΝ
      ΓΡΑΨΕ ' '
      ΓΡΑΨΕ '=======>--'
      ΓΡΑΨΕ 'Η παραπανω λεξη/φραση αντιστοιχει στον αριθμο:',Α
      ΓΡΑΨΕ '=======>--'
      ΓΡΑΨΕ_ 'Ομοιες λεξεις/φρασεις:'
      ΚΑΛΕΣΕ ΟΜΟΙΕΣ(Α,Χ)
    ΑΛΛΙΩΣ
      ΑΝ Χ<>'' ΤΟΤΕ
        ΓΡΑΨΕ '!Λανθασμενη εισοδος δεδομενων!'
      ΤΕΛΟΣ_ΑΝ
    ΤΕΛΟΣ_ΑΝ
    ΓΡΑΨΕ ' '
    ΓΡΑΨΕ '**********************************'
    ΓΡΑΨΕ '<Enter>. Εκτελεση ξανα'
    ΓΡΑΨΕ '2. Προβολη καταχωρημενων λεξεων/φρασεων'
    ΓΡΑΨΕ '3. Εξοδος'
    ΓΡΑΨΕ '4. Αναζητηση αριθμου'
    ΓΡΑΨΕ '5. Αναζητηση λεξης/φρασης'
    ΓΡΑΨΕ '6. Διαγραφη λεξης/φρασης'
    ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
      ΔΙΑΒΑΣΕ Χ
    ΜΕΧΡΙΣ_ΟΤΟΥ Χ='2' Η X='3' Η X='' Η Χ='4'  Η Χ='5'  Η Χ='6'
    ΑΝ Χ='2' ΤΟΤΕ
      ΚΑΛΕΣΕ ΠΡΟΒΟΛΗ
    ΑΛΛΙΩΣ_ΑΝ Χ='4' ΤΟΤΕ
      ΚΑΛΕΣΕ ΑΝ_ΑΡ
    ΑΛΛΙΩΣ_ΑΝ Χ='6' ΤΟΤΕ
      ΚΑΛΕΣΕ ΔΙΑΓ
    ΑΛΛΙΩΣ_ΑΝ Χ='5' ΤΟΤΕ
      ΚΑΛΕΣΕ ΑΝ_ΛΕΞ
    ΤΕΛΟΣ_ΑΝ
    ΚΑΘΑΡΙΣΕ_ΟΘΟΝΗ
  ΜΕΧΡΙΣ_ΟΤΟΥ Χ='3'
  ΑΝ ΑΛΛΑΓΗ=ΑΛΗΘΗΣ ΤΟΤΕ
    ΚΑΘΑΡΙΣΕ_ΟΘΟΝΗ
    ΓΡΑΨΕ 'Γινεται ταξινομηση'
    ΓΡΑΨΕ 'Ισως χαθουν δεδομενα εαν διακοπει'
    ΚΑΛΕΣΕ ΤΑΞΙΝ
  ΤΕΛΟΣ_ΑΝ
  ΚΛΕΙΣΕ_ΑΡΧΕΙΟ ΚΑΤ
  ΚΛΕΙΣΕ_ΠΑΡΑΘΥΡΟ
ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ
 
ΔΙΑΔΙΚΑΣΙΑ ΟΜΟΙΕΣ(Α,Χ)
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ:Α,ΜΑΧ,Φ
  ΧΑΡΑΚΤΗΡΕΣ:Χ,Π
ΑΡΧΗ
  Φ <-- 0
  ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΚΑΤ,1
  ΜΑΧ <-- ΜΕΓΕΘΟΣ_ΑΡΧΕΙΟΥ (ΚΑΤ)
  ΓΙΑ Ι ΑΠΟ 1 ΜΕΧΡΙ ΜΑΧ
    ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ ΚΑΤ,Π
    ΑΝ  ΣΥΝΤΟΜΗ(Π)=Α ΚΑΙ Χ<>Π ΤΟΤΕ
      Φ <-- Φ+1
      ΑΝ Φ<>1 ΤΟΤΕ
        ΓΡΑΨΕ_ ', '+Π
      ΑΛΛΙΩΣ
        ΓΡΑΨΕ_ Π
      ΤΕΛΟΣ_ΑΝ
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΑΝ Φ=0 ΤΟΤΕ
    ΓΡΑΨΕ_ 'Δεν υπαρχει καμια ομοια καταχωρημενη ως τωρα'
  ΤΕΛΟΣ_ΑΝ
  ΓΡΑΨΕ
  ΓΡΑΨΕ '=======>--'
ΤΕΛΟΣ_ΔΙΑΔΙΚΑΣΙΑΣ
 
ΣΥΝΑΡΤΗΣΗ ΥΠΑΡΧΕΙ(Χ):ΛΟΓΙΚΗ
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ:Ι,ΜΑΧ
  ΧΑΡΑΚΤΗΡΕΣ:Χ,Π
  ΛΟΓΙΚΕΣ:Λ
ΑΡΧΗ
  Λ <-- ΨΕΥΔΗΣ
  ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΚΑΤ,1
  ΜΑΧ <-- ΜΕΓΕΘΟΣ_ΑΡΧΕΙΟΥ (ΚΑΤ)
  ΑΝ ΜΑΧ>=1 ΤΟΤΕ
    Ι <-- 0
    ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
      Ι <-- Ι+1
      ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ ΚΑΤ,Π
      ΑΝ Π=Χ ΤΟΤΕ
        Λ <-- ΑΛΗΘΗΣ
      ΤΕΛΟΣ_ΑΝ
    ΜΕΧΡΙΣ_ΟΤΟΥ Ι=ΜΑΧ Η Λ=ΑΛΗΘΗΣ
  ΤΕΛΟΣ_ΑΝ
  ΥΠΑΡΧΕΙ <-- Λ
ΤΕΛΟΣ_ΣΥΝΑΡΤΗΣΗΣ
 
ΣΥΝΑΡΤΗΣΗ ΣΥΝΤΟΜΗ(Π):ΑΚΕΡΑΙΑ
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ:Ι,Α,Β,Κ
  ΧΑΡΑΚΤΗΡΕΣ:Π
ΑΡΧΗ
  Ι <-- ΜΗΚΟΣ_ΧΑΡ(Π)
  Α <-- 0
  Κ <-- 0
  ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
    Κ <-- Κ+1
    Β <-- ΑΡΙΘ(Π,Κ)
    Α <-- Α+Β
  ΜΕΧΡΙΣ_ΟΤΟΥ Κ=Ι
  ΣΥΝΤΟΜΗ <-- Α
ΤΕΛΟΣ_ΣΥΝΑΡΤΗΣΗΣ
 
ΔΙΑΔΙΚΑΣΙΑ ΛΕΞΑ(Χ,ΛΑΘΟΣ,Α)
ΜΕΤΑΒΛΗΤΕΣ
  ΛΟΓΙΚΕΣ:ΛΑΘΟΣ
  ΑΚΕΡΑΙΕΣ:Ι,Α,Β,Κ
  ΧΑΡΑΚΤΗΡΕΣ:Χ
ΑΡΧΗ
  ΛΑΘΟΣ <-- ΨΕΥΔΗΣ
  Ι <-- ΜΗΚΟΣ_ΧΑΡ(Χ)
  Α <-- 0
  Κ <-- 0
  ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
    Κ <-- Κ+1
    Β <-- ΑΡΙΘ(Χ,Κ)
    Α <-- Α+Β
    ΑΝ Β=-1 ΤΟΤΕ
      ΛΑΘΟΣ <-- ΑΛΗΘΗΣ
    ΤΕΛΟΣ_ΑΝ
  ΜΕΧΡΙΣ_ΟΤΟΥ Κ=Ι Η ΛΑΘΟΣ=ΑΛΗΘΗΣ
  ΑΝ Α=0 ΤΟΤΕ
    ΛΑΘΟΣ <-- ΑΛΗΘΗΣ
  ΤΕΛΟΣ_ΑΝ
ΤΕΛΟΣ_ΔΙΑΔΙΚΑΣΙΑΣ
 
ΣΥΝΑΡΤΗΣΗ ΑΡΙΘ(Χ,Κ):ΑΚΕΡΑΙΑ
ΜΕΤΑΒΛΗΤΕΣ
  ΧΑΡΑΚΤΗΡΕΣ:Χ
  ΑΚΕΡΑΙΕΣ:Π,Κ
ΑΡΧΗ
  ΑΝ Χ[Κ]='Α' ΤΟΤΕ
    Π <-- 1
  ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='Β' ΤΟΤΕ
    Π <-- 2
  ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='Γ' ΤΟΤΕ
    Π <-- 3
  ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='Δ' ΤΟΤΕ
    Π <-- 4
  ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='Ε' ΤΟΤΕ
    Π <-- 5
  ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='Ζ' ΤΟΤΕ
    Π <-- 7
  ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='Η' ΤΟΤΕ
    Π <-- 8
  ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='Θ' ΤΟΤΕ
    Π <-- 9
  ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='Ι' ΤΟΤΕ
    Π <-- 10
  ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='Κ' ΤΟΤΕ
    Π <-- 20
  ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='Λ' ΤΟΤΕ
    Π <-- 30
  ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='Μ' ΤΟΤΕ
    Π <-- 40
  ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='Ν' ΤΟΤΕ
    Π <-- 50
  ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='Ξ' ΤΟΤΕ
    Π <-- 60
  ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='Ο' ΤΟΤΕ
    Π <-- 70
  ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='Π' ΤΟΤΕ
    Π <-- 80
  ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='Ρ' ΤΟΤΕ
    Π <-- 100
  ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='Σ' ΤΟΤΕ
    Π <-- 200
  ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='Τ' ΤΟΤΕ
    Π <-- 300
  ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='Υ' ΤΟΤΕ
    Π <-- 400
  ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='Φ' ΤΟΤΕ
    Π <-- 500
  ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='Χ' ΤΟΤΕ
    Π <-- 600
  ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='Ψ' ΤΟΤΕ
    Π <-- 700
  ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='Ω' ΤΟΤΕ
    Π <-- 800
  ΑΛΛΙΩΣ_ΑΝ Χ[Κ]=' ' ΤΟΤΕ
    Π <-- 0
  ΑΛΛΙΩΣ
    Π <-- -1
  ΤΕΛΟΣ_ΑΝ
  ΑΡΙΘ <-- Π
ΤΕΛΟΣ_ΣΥΝΑΡΤΗΣΗΣ
 
ΔΙΑΔΙΚΑΣΙΑ ΠΡΟΒΟΛΗ
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ:Ι,ΜΑΧ,Μ,Α,ΣΕΙΡΑ
  ΧΑΡΑΚΤΗΡΕΣ:Χ,ΑΡΧ,ΕΠ
ΑΡΧΗ
  ΚΑΘΑΡΙΣΕ_ΟΘΟΝΗ
  ΜΑΧ <-- ΜΕΓΕΘΟΣ_ΑΡΧΕΙΟΥ (ΚΑΤ)
  ΑΝ ΜΑΧ>=1 ΤΟΤΕ
    ΓΡΑΨΕ '1.Προβολη ολων'
    ΓΡΑΨΕ '2.Επιλεκτικη προβολη'
    ΓΡΑΨΕ '3.Εξοδος'
    ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
      ΔΙΑΒΑΣΕ Χ
    ΜΕΧΡΙΣ_ΟΤΟΥ Χ='1' Η Χ='2' Η Χ='3'
    ΚΑΘΑΡΙΣΕ_ΟΘΟΝΗ
    ΑΝ Χ='1' ΤΟΤΕ
      ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΚΑΤ,1
      Ι <-- 0
      Μ <-- 0
      ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
        Ι <-- Ι+1
        ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ ΚΑΤ,Χ
        Α <-- ΣΥΝΤΟΜΗ(Χ)
        ΓΡΑΨΕ Ι,'.',Χ,'--->',Α
        Μ <-- Μ+1
        ΑΝ Μ=21 ΤΟΤΕ
          ΓΡΑΨΕ '=========================='
          ΓΡΑΨΕ '<Enter>. Συνεχεια προβολης'
          ΓΡΑΨΕ '3. Τερματισμος προβολης'
          ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
            ΔΙΑΒΑΣΕ Χ
          ΜΕΧΡΙΣ_ΟΤΟΥ Χ='' Η Χ='3'
          ΚΑΘΑΡΙΣΕ_ΟΘΟΝΗ
          Μ <-- 0
        ΤΕΛΟΣ_ΑΝ
      ΜΕΧΡΙΣ_ΟΤΟΥ Ι=ΜΑΧ Η Χ='3'
    ΑΛΛΙΩΣ_ΑΝ Χ='2' ΤΟΤΕ
      ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
        ΓΡΑΨΕ_ 'Προβολη λεξεων/φρασεων που αρχιζουν από (γραμμα):'
        ΔΙΑΒΑΣΕ ΑΡΧ
        ΑΡΧ <-- Μ_Κ(ΑΡΧ)
        ΚΑΘΑΡΙΣΕ_ΟΘΟΝΗ
      ΜΕΧΡΙΣ_ΟΤΟΥ ΜΗΚΟΣ_ΧΑΡ(ΑΡΧ)=1 ΚΑΙ ΑΡΙΘ(ΑΡΧ,1)>=0
      ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΚΑΤ,1
      Ι <-- 0
      Μ <-- 0
      ΣΕΙΡΑ <-- 0
      ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
        Ι <-- Ι+1
        ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ ΚΑΤ,Χ
        ΑΝ ΑΡΧ=Χ[1] ΤΟΤΕ
          ΣΕΙΡΑ <-- ΣΕΙΡΑ+1
          Α <-- ΣΥΝΤΟΜΗ(Χ)
          ΓΡΑΨΕ ΣΕΙΡΑ,'.',Χ,'--->',Α
          Μ <-- Μ+1
        ΤΕΛΟΣ_ΑΝ
        ΑΝ Μ=21 ΤΟΤΕ
          ΓΡΑΨΕ '=========================='
          ΓΡΑΨΕ '<Enter>. Συνεχεια προβολης'
          ΓΡΑΨΕ '3. Τερματισμος προβολης'
          ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
            ΔΙΑΒΑΣΕ ΕΠ
          ΜΕΧΡΙΣ_ΟΤΟΥ ΕΠ='' Η ΕΠ='3' Η Χ[1]>ΑΡΧ
          ΚΑΘΑΡΙΣΕ_ΟΘΟΝΗ
          Μ <-- 0
        ΤΕΛΟΣ_ΑΝ
      ΜΕΧΡΙΣ_ΟΤΟΥ Ι=ΜΑΧ Η ΕΠ='3' Η Χ[1]>ΑΡΧ
      ΑΝ ΣΕΙΡΑ=0 ΤΟΤΕ
        ΓΡΑΨΕ 'Καμια λεξη/φραση δεν αρχιζει απο:',ΑΡΧ
      ΤΕΛΟΣ_ΑΝ
    ΤΕΛΟΣ_ΑΝ
    ΓΡΑΨΕ '============================================'
    ΓΡΑΨΕ 'Η εμφανιση ολοκληρωθηκε,<Enter> για συνεχεια'
    ΔΙΑΒΑΣΕ Χ
  ΑΛΛΙΩΣ
    ΓΡΑΨΕ 'Δεν υπαρχουν καταχωρημενες λεξεις/φρασεις'
    ΓΡΑΨΕ '<Enter> για συνεχεια'
    ΔΙΑΒΑΣΕ Χ
  ΤΕΛΟΣ_ΑΝ
ΤΕΛΟΣ_ΔΙΑΔΙΚΑΣΙΑΣ
 
 
ΔΙΑΔΙΚΑΣΙΑ ΑΝ_ΑΡ
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ:Μ,Ι,ΜΑΧ,Α,Φ,ΣΕΙΡΑ,Μ2
  ΧΑΡΑΚΤΗΡΕΣ:Χ,ΛΕΙ
  ΛΟΓΙΚΕΣ:ΥΠ
ΑΡΧΗ
  ΜΑΧ <-- ΜΕΓΕΘΟΣ_ΑΡΧΕΙΟΥ(ΚΑΤ)
  ΑΝ ΜΑΧ>=1 ΤΟΤΕ
    ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
      ΚΑΘΑΡΙΣΕ_ΟΘΟΝΗ
      ΓΡΑΨΕ '1. Ευρεση ='
      ΓΡΑΨΕ '2. Ευρεση >='
      ΓΡΑΨΕ '3. Ευρεση <='
      ΓΡΑΨΕ '4. Ευρεση >= και <='
      ΓΡΑΨΕ '5. Εξοδος'
      ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
        ΔΙΑΒΑΣΕ ΛΕΙ
      ΜΕΧΡΙΣ_ΟΤΟΥ ΛΕΙ='1' Η ΛΕΙ='2' Η ΛΕΙ='3' Η ΛΕΙ='4' Η ΛΕΙ='5'
      ΑΝ ΛΕΙ<>'5' ΤΟΤΕ
        ΓΡΑΨΕ_ 'Αριθμος:'
        ΔΙΑΒΑΣΕ Μ
        ΑΝ  ΛΕΙ='4' ΤΟΤΕ
          ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
            ΓΡΑΨΕ_ 'Αριθμος 2 (>=',Μ,'):'
            ΔΙΑΒΑΣΕ Μ2
          ΜΕΧΡΙΣ_ΟΤΟΥ Μ2>=Μ
        ΤΕΛΟΣ_ΑΝ
        ΣΕΙΡΑ <-- 0
        ΥΠ <-- ΨΕΥΔΗΣ
        ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΚΑΤ,1
        ΚΑΘΑΡΙΣΕ_ΟΘΟΝΗ
        ΓΡΑΨΕ 'Οι παρακατω λεξεις/φρασεις ικανοποιουν τα κρητηρια'
        Ι <-- 0
        Φ <-- 0
        ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
          Ι <-- Ι+1
          ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ ΚΑΤ,Χ
          Α <-- ΣΥΝΤΟΜΗ(Χ)
          ΑΝ ΛΕΙ='1' ΤΟΤΕ
            ΑΝ Α=Μ ΤΟΤΕ
              ΥΠ <-- ΑΛΗΘΗΣ
              ΣΕΙΡΑ <-- ΣΕΙΡΑ+1
              Φ <-- Φ+1
              ΓΡΑΨΕ ΣΕΙΡΑ,'.', Χ
            ΤΕΛΟΣ_ΑΝ
          ΑΛΛΙΩΣ_ΑΝ ΛΕΙ='2' ΤΟΤΕ
            ΑΝ Α>=Μ ΤΟΤΕ
              ΥΠ <-- ΑΛΗΘΗΣ
              Φ <-- Φ+1
              ΣΕΙΡΑ <-- ΣΕΙΡΑ+1
              ΓΡΑΨΕ ΣΕΙΡΑ,'.',Χ,'-->',Α
            ΤΕΛΟΣ_ΑΝ
          ΑΛΛΙΩΣ_ΑΝ ΛΕΙ='3' ΤΟΤΕ
            ΑΝ Α<=Μ ΤΟΤΕ
              ΥΠ <-- ΑΛΗΘΗΣ
              Φ <-- Φ+1
              ΣΕΙΡΑ <-- ΣΕΙΡΑ+1
              ΓΡΑΨΕ ΣΕΙΡΑ,'.',Χ,'-->',Α
            ΤΕΛΟΣ_ΑΝ
          ΑΛΛΙΩΣ_ΑΝ ΛΕΙ='4' ΤΟΤΕ
            ΑΝ Α>=Μ ΚΑΙ Α<=Μ2 ΤΟΤΕ
              ΥΠ <-- ΑΛΗΘΗΣ
              Φ <-- Φ+1
              ΣΕΙΡΑ <-- ΣΕΙΡΑ+1
              ΓΡΑΨΕ ΣΕΙΡΑ,'.',Χ,'-->',Α
            ΤΕΛΟΣ_ΑΝ
          ΤΕΛΟΣ_ΑΝ
          ΑΝ Φ=19 ΤΟΤΕ
            Φ <-- 0
            ΓΡΑΨΕ '=========================='
            ΓΡΑΨΕ '<Enter>. Συνεχεια αναζητησης'
            ΓΡΑΨΕ '3. Τερματισμος αναζητησης'
            ΔΙΑΒΑΣΕ Χ
            ΚΑΘΑΡΙΣΕ_ΟΘΟΝΗ
          ΤΕΛΟΣ_ΑΝ
        ΜΕΧΡΙΣ_ΟΤΟΥ Ι=ΜΑΧ Η Χ='3'
        ΑΝ ΥΠ=ΨΕΥΔΗΣ ΤΟΤΕ
          ΓΡΑΨΕ 'Καμια λεξη/φραση δεν ικανοποιει τα κρητηρια'
        ΤΕΛΟΣ_ΑΝ
        ΓΡΑΨΕ '========================'
        ΓΡΑΨΕ 'Η αναζητηση ολοκληρωθηκε'
        ΓΡΑΨΕ '<Enter>. για επαναληψη'
        ΓΡΑΨΕ '3. Επιστροφη στην κανονικη λειτουργεια'
        ΔΙΑΒΑΣΕ Χ
      ΤΕΛΟΣ_ΑΝ
    ΜΕΧΡΙΣ_ΟΤΟΥ Χ='3' Η ΛΕΙ='5'
  ΤΕΛΟΣ_ΑΝ
ΤΕΛΟΣ_ΔΙΑΔΙΚΑΣΙΑΣ
 
ΔΙΑΔΙΚΑΣΙΑ ΔΙΑΓ
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ:Ι,ΜΑΧ,Θ
  ΧΑΡΑΚΤΗΡΕΣ:Χ
ΑΡΧΗ
  ΚΑΘΑΡΙΣΕ_ΟΘΟΝΗ
  ΜΑΧ <-- ΜΕΓΕΘΟΣ_ΑΡΧΕΙΟΥ (ΚΑΤ)
  ΑΝ ΜΑΧ>=1 ΤΟΤΕ
    ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
      ΚΑΘΑΡΙΣΕ_ΟΘΟΝΗ
      ΓΡΑΨΕ 'Δωσε αριθμο καταχωρησης (μεγιστο',ΜΑΧ,'):'
      ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
        ΔΙΑΒΑΣΕ Θ
      ΜΕΧΡΙΣ_ΟΤΟΥ Θ>=1 ΚΑΙ Θ<=ΜΑΧ
      ΚΑΘΑΡΙΣΕ_ΟΘΟΝΗ
      ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΚΑΤ,Θ
      ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ ΚΑΤ,Χ
      ΓΡΑΨΕ 'Διαγραφη του: "',Χ,'" ?'
      ΓΡΑΨΕ '=======>--'
      ΓΡΑΨΕ '1.Οχι/Εξοδος'
      ΓΡΑΨΕ '2.Επιλογη αλλης'
      ΓΡΑΨΕ '6.Ναι'
      ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
        ΔΙΑΒΑΣΕ Χ
      ΜΕΧΡΙΣ_ΟΤΟΥ Χ='1' Η Χ='2' Η Χ='6'
    ΜΕΧΡΙΣ_ΟΤΟΥ Χ='1' Η Χ='6'
    ΑΝ Χ='6' ΤΟΤΕ
      ΓΙΑ Ι ΑΠΟ 1 ΜΕΧΡΙ ΜΑΧ-Θ
        ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΚΑΤ,Θ+Ι
        ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ ΚΑΤ,Χ
        ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΚΑΤ,Θ+Ι-1
        ΓΡΑΨΕ_ΑΡΧΕΙΟ ΚΑΤ,Χ
      ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
      ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΚΑΤ,ΜΑΧ
      ΑΠΟΚΟΨΕ_ΑΡΧΕΙΟ ΚΑΤ
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΑΝ
ΤΕΛΟΣ_ΔΙΑΔΙΚΑΣΙΑΣ
 
ΔΙΑΔΙΚΑΣΙΑ ΤΑΞΙΝ
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ:ΜΑΧ,Ι,Κ
  ΧΑΡΑΚΤΗΡΕΣ:Χ1,Χ2,Π
  ΛΟΓΙΚΕΣ:ΕΞΩ
ΑΡΧΗ
  ΜΑΧ <-- ΜΕΓΕΘΟΣ_ΑΡΧΕΙΟΥ (ΚΑΤ)
  ΑΝ ΜΑΧ>=2 ΤΟΤΕ
    ΠΗΓΑΙΝΕ_ΧΥ 1,5
    ΓΡΑΨΕ 'Ολοκληρωθηκε:'
    Ι <-- 1
    ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
      ΕΞΩ <-- ΑΛΗΘΗΣ
      Κ <-- ΜΑΧ
      ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
        ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΚΑΤ,Κ
        ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ ΚΑΤ,Χ2
        ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΚΑΤ,Κ-1
        ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ ΚΑΤ,Χ1
        ΑΝ Χ2<Χ1 ΤΟΤΕ
          ΕΞΩ <-- ΨΕΥΔΗΣ
          ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΚΑΤ,Κ
          ΓΡΑΨΕ_ΑΡΧΕΙΟ ΚΑΤ,Χ1
          ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΚΑΤ,Κ-1
          ΓΡΑΨΕ_ΑΡΧΕΙΟ ΚΑΤ,Χ2
        ΤΕΛΟΣ_ΑΝ
        Κ <-- Κ-1
      ΜΕΧΡΙΣ_ΟΤΟΥ Κ=1
      ΠΗΓΑΙΝΕ_ΧΥ 14,5
      ΓΡΑΨΕ (Ι/ΜΑΧ)*100,'%'
      Ι <-- Ι+1
    ΜΕΧΡΙΣ_ΟΤΟΥ Ι=ΜΑΧ  Η ΕΞΩ=ΑΛΗΘΗΣ
  ΤΕΛΟΣ_ΑΝ
ΤΕΛΟΣ_ΔΙΑΔΙΚΑΣΙΑΣ
 
ΔΙΑΔΙΚΑΣΙΑ ΑΝ_ΛΕΞ
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ:Ι,Θ,ΜΑΧ
  ΧΑΡΑΚΤΗΡΕΣ:ΑΡΧ,ΕΠ,Π
ΑΡΧΗ
  ΜΑΧ <-- ΜΕΓΕΘΟΣ_ΑΡΧΕΙΟΥ (ΚΑΤ)
  ΑΝ ΜΑΧ>=1 ΤΟΤΕ
    ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
      ΚΑΘΑΡΙΣΕ_ΟΘΟΝΗ
      ΓΡΑΨΕ_ 'Αναζητηση της λεξης/φρασης:'
      ΔΙΑΒΑΣΕ Π
      Π <-- Μ_Κ(Π)
      Ι <-- 0
      Θ <-- 0
      ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΚΑΤ,1
      ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
        Ι <-- Ι+1
        ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ ΚΑΤ,ΑΡΧ
        ΑΝ ΑΡΧ=Π ΤΟΤΕ
          Θ <-- Ι
        ΤΕΛΟΣ_ΑΝ
      ΜΕΧΡΙΣ_ΟΤΟΥ Ι=ΜΑΧ Η Θ<>0
      ΓΡΑΨΕ '=======>--'
      ΑΝ Θ<>0 ΤΟΤΕ
        ΓΡΑΨΕ 'Η λεξη/φραση βρισκεται στην θεση:',Θ
      ΑΛΛΙΩΣ
        ΓΡΑΨΕ 'Δεν βρεθηκε'
      ΤΕΛΟΣ_ΑΝ
      ΓΡΑΨΕ '=======>--'
      ΓΡΑΨΕ '1.Εξοδος'
      ΓΡΑΨΕ '<Enter>. Εκτελεση ξανα'
      ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
        ΔΙΑΒΑΣΕ ΕΠ
      ΜΕΧΡΙΣ_ΟΤΟΥ ΕΠ='1' Η ΕΠ=''
    ΜΕΧΡΙΣ_ΟΤΟΥ  ΕΠ='1'
  ΤΕΛΟΣ_ΑΝ
ΤΕΛΟΣ_ΔΙΑΔΙΚΑΣΙΑΣ
 
ΣΥΝΑΡΤΗΣΗ Μ_Κ(Χ):ΧΑΡΑΚΤΗΡΕΣ
ΜΕΤΑΒΛΗΤΕΣ
  ΧΑΡΑΚΤΗΡΕΣ:Χ,ΕΠ
  ΑΚΕΡΑΙΕΣ:ΜΑΧ,Κ
ΑΡΧΗ
  ΜΑΧ <-- ΜΗΚΟΣ_ΧΑΡ(Χ)
  ΓΙΑ Κ ΑΠΟ 1 ΜΕΧΡΙ ΜΑΧ
    ΑΝ Χ[Κ]='α' ΤΟΤΕ
      Χ[Κ] <-- 'Α'                                                         
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='β' ΤΟΤΕ
      Χ[Κ] <-- 'Β'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='γ' ΤΟΤΕ
      Χ[Κ] <-- 'Γ'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='δ' ΤΟΤΕ
      Χ[Κ] <-- 'Δ'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='ε' ΤΟΤΕ
      Χ[Κ] <-- 'Ε'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='ζ' ΤΟΤΕ
      Χ[Κ] <-- 'Ζ'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='η' ΤΟΤΕ
      Χ[Κ] <-- 'Η'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='θ' ΤΟΤΕ
      Χ[Κ] <-- 'Θ'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='ι' ΤΟΤΕ
      Χ[Κ] <-- 'Ι'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='κ' ΤΟΤΕ
      Χ[Κ] <-- 'Κ'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='λ' ΤΟΤΕ
      Χ[Κ] <-- 'Λ'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='μ' ΤΟΤΕ
      Χ[Κ] <-- 'Μ'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='ν' ΤΟΤΕ
      Χ[Κ] <-- 'Ν'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='ξ' ΤΟΤΕ
      Χ[Κ] <-- 'Ξ'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='ο' ΤΟΤΕ
      Χ[Κ] <-- 'Ο'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='π' ΤΟΤΕ
      Χ[Κ] <-- 'Π'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='ρ' ΤΟΤΕ
      Χ[Κ] <-- 'Ρ'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='σ' Η Χ[Κ]='ς' ΤΟΤΕ
      Χ[Κ] <-- 'Σ'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='τ' ΤΟΤΕ
      Χ[Κ] <-- 'Τ'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='υ' ΤΟΤΕ
      Χ[Κ] <-- 'Υ'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='φ' ΤΟΤΕ
      Χ[Κ] <-- 'Φ'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='χ' ΤΟΤΕ
      Χ[Κ] <-- 'Χ'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='ψ' ΤΟΤΕ
      Χ[Κ] <-- 'Ψ'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='ω' ΤΟΤΕ
      Χ[Κ] <-- 'Ω'
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  Μ_Κ <--  Χ
ΤΕΛΟΣ_ΣΥΝΑΡΤΗΣΗΣ

Κατεβαστε και το exe

Panos_K · 10-09-08

Στο προγραμμα SUDOKU καντε αντικατασταση την διαδικασια "ΕΙΣΟΔΟΣ(ΣΟΥ,ΠΙΑΣΜΕΝΕΣ)"
με την παρακατω

Ειναι κορυφη

Code:

ΔΙΑΔΙΚΑΣΙΑ ΕΙΣΟΔΟΣ(ΣΟΥ,ΠΙΑΣΜΕΝΕΣ)
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ:Χ,Υ,ΑΡ,ΣΟΥ[81],ΘΧ,ΘΥ
  ΛΟΓΙΚΕΣ:ΠΙΑΣΜΕΝΕΣ[81]
  ΧΑΡΑΚΤΗΡΕΣ:Κ
ΑΡΧΗ
  ΠΗΓΑΙΝΕ_ΧΥ 44,15
  ΓΡΑΨΕ '-> **By Panos_K** <-'
  ΠΗΓΑΙΝΕ_ΧΥ 30,1
  ΓΡΑΨΕ 'Χρησιμοποιησε τα πληκτρα [8,2,4,6] για αλλαγη θεσης'
  ΠΗΓΑΙΝΕ_ΧΥ 30,3
  ΓΡΑΨΕ 'Πιεσε το [5] για εισαγωγη αριθμου στην θεση'
  ΠΗΓΑΙΝΕ_ΧΥ 30,5
  ΓΡΑΨΕ '!!Αν βαλεις το [0] σε μια θεση, αδειαζει η θεση!!'
  ΠΗΓΑΙΝΕ_ΧΥ 30,7
  ΓΡΑΨΕ 'Πληκτρολογησε τον αριθμο και επειτα πιεσε <Enter>'
  ΠΗΓΑΙΝΕ_ΧΥ 30,9
  ΓΡΑΨΕ 'Για να δεις την λυση πιεσε [0]'
  ΠΗΓΑΙΝΕ_ΧΥ 1,1
  ΓΡΑΨΕ '+--+--+--#--+--+--#--+--+--+'
  ΓΡΑΨΕ '|  |  |  |  |  |  |  |  |  |'
  ΓΡΑΨΕ '+--+--+--#--+--+--#--+--+--+'
  ΓΡΑΨΕ '|  |  |  |  |  |  |  |  |  |'
  ΓΡΑΨΕ '+--+--+--#--+--+--#--+--+--+'
  ΓΡΑΨΕ '|  |  |  |  |  |  |  |  |  |'
  ΓΡΑΨΕ '+++++++++#++++++++#+++++++++'
  ΓΡΑΨΕ '|  |  |  |  |  |  |  |  |  |'
  ΓΡΑΨΕ '+--+--+--#--+--+--#--+--+--+'
  ΓΡΑΨΕ '|  |  |  |  |  |  |  |  |  |'
  ΓΡΑΨΕ '+--+--+--#--+--+--#--+--+--+'
  ΓΡΑΨΕ '|  |  |  |  |  |  |  |  |  |'
  ΓΡΑΨΕ '+++++++++#++++++++#+++++++++'
  ΓΡΑΨΕ '|  |  |  |  |  |  |  |  |  |'
  ΓΡΑΨΕ '+--+--+--#--+--+--#--+--+--+'
  ΓΡΑΨΕ '|  |  |  |  |  |  |  |  |  |'
  ΓΡΑΨΕ '+--+--+--#--+--+--#--+--+--+'
  ΓΡΑΨΕ '|  |  |  |  |  |  |  |  |  |'
  ΓΡΑΨΕ '+++++++++#++++++++#+++++++++'
  ΘΧ <-- 3
  ΘΥ <-- 2
  ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
    ΠΗΓΑΙΝΕ_ΧΥ ΘΧ,ΘΥ
    ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
      Κ <-- READKEY
      ΑΝ Κ='8' ΤΟΤΕ
        ΘΥ <-- ΘΥ-2
      ΑΛΛΙΩΣ_ΑΝ Κ='6' ΤΟΤΕ
        ΘΧ <-- ΘΧ+3
      ΑΛΛΙΩΣ_ΑΝ Κ='4' ΤΟΤΕ
        ΘΧ <-- ΘΧ-3
      ΑΛΛΙΩΣ_ΑΝ Κ='2' ΤΟΤΕ
        ΘΥ <-- ΘΥ+2
      ΤΕΛΟΣ_ΑΝ
      ΑΝ ΘΧ>27 ΤΟΤΕ
        ΘΧ <-- 3
      ΑΛΛΙΩΣ_ΑΝ ΘΧ<3 ΤΟΤΕ
        ΘΧ <-- 27
      ΤΕΛΟΣ_ΑΝ
      ΑΝ ΘΥ>18 ΤΟΤΕ
        ΘΥ <-- 2
      ΑΛΛΙΩΣ_ΑΝ ΘΥ<2 ΤΟΤΕ
        ΘΥ <-- 18
      ΤΕΛΟΣ_ΑΝ
      ΠΗΓΑΙΝΕ_ΧΥ ΘΧ,ΘΥ
    ΜΕΧΡΙΣ_ΟΤΟΥ Κ='5' Η Κ='0'
    ΑΝ Κ='5' ΤΟΤΕ
      ΔΙΑΒΑΣΕ ΑΡ
      Χ <-- Α_Μ(ΘΧ/3)
      Υ <-- Α_Μ(ΘΥ/2)
      ΣΟΥ[Χ+(Υ-1)*9] <-- ΑΡ
      ΑΝ ΑΡ<>0 ΤΟΤΕ
        ΑΝ ΑΠΟΔΕΚΤΟ(ΣΟΥ,Χ+(Υ-1)*9)=ΨΕΥΔΗΣ ΤΟΤΕ
          ΣΟΥ[Χ+(Υ-1)*9] <-- 0
          ΠΗΓΑΙΝΕ_ΧΥ ΘΧ-1,ΘΥ
          ΓΡΑΨΕ ' '
        ΑΛΛΙΩΣ
          ΠΙΑΣΜΕΝΕΣ[Χ+(Υ-1)*9] <-- ΑΛΗΘΗΣ
        ΤΕΛΟΣ_ΑΝ
      ΑΛΛΙΩΣ
        ΠΙΑΣΜΕΝΕΣ[Χ+(Υ-1)*9] <-- ΨΕΥΔΗΣ
        ΠΗΓΑΙΝΕ_ΧΥ ΘΧ-1,ΘΥ
        ΓΡΑΨΕ ' '
      ΤΕΛΟΣ_ΑΝ
    ΤΕΛΟΣ_ΑΝ
  ΜΕΧΡΙΣ_ΟΤΟΥ Κ='0'
  ΚΑΘΑΡΙΣΕ_ΟΘΟΝΗ
ΤΕΛΟΣ_ΔΙΑΔΙΚΑΣΙΑΣ

Μπορειτε να κατεβασετε και το exe

Panos_K · 07-09-08

Αρχική Δημοσίευση από kiriakoskiriakos:
Να ρωτήσω κάτι για την τρίλιζα, οι κινήσεις του ΑΙ είναι τυχαίες ή επιλέγει με βάση μια στρατηγική?

Επίσης θα μπορούσες να ανεβάσεις τον κώδικα ίσως για να δώσει ιδέες και να βοηθήσει κάποιους που θέλουν να ασχοληθούν

Καποιες κινησεις ειναι τυχαιες και καποιες οχι.
Η τιμη που επιστρεφει η συναρτηση ΠΙΣΙ αντιστοιχει στην θεση που θα μπει το "Ο"
Η συναρτηση Α_Ψ1 επιστρεφει την τιμη "ΑΛΗΘΗΣ" αν μπορει να νικησει ο υπολογιστης στην επομενη κινηση, βαζοντας στην θεση Ι (εφοσον δεν ειναι πιασμενη) το "Ο", αλλιως την τιμη "ΨΕΥΔΗΣ".
Η συναρτηση Α_Ψ2 ελεγχει αν μπορει να νικησει ο ανθρωπος στην επομενη κινηση (ιδια λογικη με την Α_Ψ1 μονο που αντι για "Ο" βαζει "Χ") και επιστρεφει την καταλληλη τιμη.
Αν η Α_Ψ1 παρει την τιμη "ΑΛΗΘΗΣ" τοτε στην καταλληλη θεση βαζει "Ο" και νικαει
Αν η Α_Ψ1 δεν παρει την τιμη "ΑΛΗΘΗΣ" τοτε
καλει την Α_Ψ2.
Αν η Α_Ψ2 παρει την τιμη ΑΛΗΘΗΣ (που σημαινει οτι νικαει ο ανθρωπος στην επομενη κινηση) στην καταλληλη θεση βαζει "Ο" για να μην νικησει ο ανθρωπος.
Αν και οι 2 συναρτησεις εχουν την τιμη ψευδης τοτε διαλεγει στην τυχη σε ποια θεση θα βαλει "Ο"

Καθε θεση του πινακα θ[9] αντιστοιχει και σε ενα κουτακι της τριλιζας.
Στις θεσεις που εχει βαλει ο ανθρωπος "Χ" μπαινει η τιμη "Χ"
Στις θεσεις που εχει βαλει ο υπολογιστης "Ο" μπαινει η τιμη "Ο"
Στις θεσεις που δεν εχει βαλει κανενας μπαινει η τιμη "Κ"

(Η συναρτηση ΠΟΙΟΣ επιστρεφει "Ο" αν νικαει ο υπολογιστης και "Χ" αν νικαει ο ανθρωπος. "Κ" αν δεν νικαει κανενας)

Αυτα

Code:

ΣΥΝΑΡΤΗΣΗ ΠΙΣΙ(Θ):ΑΚΕΡΑΙΑ
ΜΕΤΑΒΛΗΤΕΣ
ΑΚΕΡΑΙΕΣ:Ι,Κ,ΠΡ
ΧΑΡΑΚΤΗΡΕΣ:Θ[9],ΝΙΚΗ
ΛΟΓΙΚΕΣ:ΒΡ
ΑΡΧΗ
!ΜΗΠΩΣ ΝΙΚΑΕΙ
ΠΡ <-- 0
Ι <-- 0
ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
Ι <-- Ι+1
ΒΡ <-- Α_Ψ1(Θ,Ι)
ΑΝ ΒΡ=ΑΛΗΘΗΣ ΤΟΤΕ
ΠΡ <-- Ι
ΤΕΛΟΣ_ΑΝ
ΜΕΧΡΙΣ_ΟΤΟΥ ΒΡ=ΑΛΗΘΗΣ Η Ι=9
!ΜΗΠΩΣ ΧΑΝΕΙ
ΑΝ ΠΡ=0 ΤΟΤΕ
Ι <-- 0
ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
Ι <-- Ι+1
ΒΡ <-- Α_Ψ2(Θ,Ι)
ΑΝ ΒΡ=ΑΛΗΘΗΣ ΤΟΤΕ
ΠΡ <-- Ι
ΤΕΛΟΣ_ΑΝ
ΜΕΧΡΙΣ_ΟΤΟΥ ΒΡ=ΑΛΗΘΗΣ Η Ι=9
ΤΕΛΟΣ_ΑΝ
Ι <-- 0
ΑΝ ΠΡ=0 ΤΟΤΕ
ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
ΠΡ <-- ΤΥΧΑΙΟΣ(9)
ΜΕΧΡΙΣ_ΟΤΟΥ ΠΡ<>0
Ι <-- Ι+1
ΜΕΧΡΙΣ_ΟΤΟΥ Θ[ΠΡ]='Κ' Η Ι=100 ! Ναι ειναι λιγο μπακαλιστικο . . . :Ρ
ΤΕΛΟΣ_ΑΝ
ΑΝ Ι=100 ΤΟΤΕ
ΠΡ <-- 9
ΤΕΛΟΣ_ΑΝ
ΠΙΣΙ <-- ΠΡ
ΤΕΛΟΣ_ΣΥΝΑΡΤΗΣΗΣ
 
ΣΥΝΑΡΤΗΣΗ Α_Ψ2(Θ,Ι):ΛΟΓΙΚΗ
ΜΕΤΑΒΛΗΤΕΣ
ΑΚΕΡΑΙΕΣ:Ι
ΛΟΓΙΚΕΣ:ΠΡ
ΧΑΡΑΚΤΗΡΕΣ:Θ[9],ΝΙΚΗ
ΑΡΧΗ
ΠΡ <-- ΨΕΥΔΗΣ
ΑΝ Θ[Ι]='Κ' ΤΟΤΕ
Θ[Ι] <-- 'Χ'
ΝΙΚΗ <-- ΠΟΙΟΣ(Θ)
ΑΝ ΝΙΚΗ='Χ' ΤΟΤΕ
ΠΡ <-- ΑΛΗΘΗΣ
ΤΕΛΟΣ_ΑΝ
ΤΕΛΟΣ_ΑΝ
Α_Ψ2 <-- ΠΡ
ΤΕΛΟΣ_ΣΥΝΑΡΤΗΣΗΣ
ΣΥΝΑΡΤΗΣΗ Α_Ψ1(Θ,Ι):ΛΟΓΙΚΗ
ΜΕΤΑΒΛΗΤΕΣ
ΑΚΕΡΑΙΕΣ:Ι
ΛΟΓΙΚΕΣ:ΠΡ
ΧΑΡΑΚΤΗΡΕΣ:Θ[9],ΝΙΚΗ
ΑΡΧΗ
ΠΡ <-- ΨΕΥΔΗΣ
ΑΝ Θ[Ι]='Κ' ΤΟΤΕ
Θ[Ι] <-- 'Ο'
ΝΙΚΗ <-- ΠΟΙΟΣ(Θ)
ΑΝ ΝΙΚΗ='Ο' ΤΟΤΕ
ΠΡ <-- ΑΛΗΘΗΣ
ΤΕΛΟΣ_ΑΝ
ΤΕΛΟΣ_ΑΝ
Α_Ψ1 <-- ΠΡ
ΤΕΛΟΣ_ΣΥΝΑΡΤΗΣΗΣ

Άλλα μηνύματα του μέλους Panos_K σε αυτό το thread

Panos_K

Νεοφερμένος

Συνημμένα

Panos_K

Νεοφερμένος

Συνημμένα

Panos_K

Νεοφερμένος

Λοιπές Σελίδες